module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/ows-text-campaigns/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "${var.environment}-fansifter.theorchard.io"
}

data "aws_acm_certificate" "certificate" {
  domain   = "*.${var.environment}-fansifter.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_msk_cluster" "kafka_fansifter" {
  cluster_name = "${var.environment}-${var.msk_cluster_name}"
}

module "ows_service_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.8.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family

  desired_task_count                       = 2
  minimum_capacity                         = 2
  maximum_capacity                         = 4
  task_cpu                                 = 1024
  task_memory                              = 2048
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_private_subnet_ids
  https_listener_allow_prefix_list_names = [
    "prod-orcd-private-subnet-prefix-list",
  ]

  splitio_enabled                = false
  ows_machine_to_machine_enabled = false

  iam_managed_policy_attachments = [
    aws_iam_policy.assets_s3_rw_policy.arn,
    aws_iam_policy.browser_upload_sts_policy.arn,
    aws_iam_policy.ows_text_campaigns_kms_policy.arn,
    aws_iam_policy.dynamodb_access_policy.arn,
  ]

  execution_role_iam_managed_policy_attachments = [
    aws_iam_policy.secrets_manager_extra_read_policy.arn,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      SENTRY_DSN = module.sentry.sentry_key_dsn_public_output
    },
    {
      REDIS_HOST = module.redis_elasticache.redis_primary_endpoint_address
    },
    {
      POSTGRES_HOST = var.postgres_host
    },
    {
      POSTGRES_PORT = var.postgres_port
    },
    {
      POSTGRES_NAME = var.postgres_name
    },
    {
      POSTGRES_USER = var.postgres_username
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      TWILIO_ACCOUNT_SID = var.twilio_account_sid
    },
    {
      ASSETS_IAM_ROLE_ARN = aws_iam_role.browser_upload_role.arn
    },
    {
      ASSETS_BUCKET_NAME = module.assets_s3_bucket.s3_bucket_name_output
    },
    {
      ASSETS_CDN_DOMAIN = local.assets_cloudfront_domain
    },
    {
      KMS_KEY_ID = aws_kms_alias.kms_key_alias.name
    },
    {
      KAFKA_BOOTSTRAP_SERVERS = data.aws_msk_cluster.kafka_fansifter.bootstrap_brokers_tls
    },
    {
      FAN_STATES_DYNAMODB_TABLENAME = module.fan_states_dynamodb_table.aws_dynamodb_table_id
    },
  ]

  secrets = [
    {
      POSTGRES_PASSWORD = "${var.environment}/${var.service_name}/RDS_TEXT_CAMPAIGNS_PASSWORD"
    },
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
    {
      SNOWFLAKE_KEY_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY_PASSPHRASE"
    },
    {
      TWILIO_AUTH_TOKEN = "${var.environment}/${var.service_name}/TWILIO_AUTH_TOKEN"
    },
    {
      PREFERENCE_CENTER_SECRET_KEY = local.preference_center_secret_key_name
    }
  ]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.7"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.application_family]

  service_4xx_monitor_enabled = false

  service_cpu_monitor_evaluation_function = "avg"
  service_cpu_time_window                 = "last_10m"

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}

module "sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  application_family = var.application_family
}

module "redis_elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"

  providers = {
    aws.dns = aws
  }

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.id

  cache_engine               = "redis"
  redis_engine_version       = "7.0"
  cache_parameter_group_name = "default.redis7"
  cache_node_type            = "cache.t4g.small"
  cache_node_count           = 1
  cache_subnet_group_name    = "${var.environment}-elasticache-subnet-group"
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}