module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.application_family
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/resonance-engine/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "${var.environment}-fansifter.theorchard.io"
}

data "aws_msk_cluster" "kafka_fansifter" {
  cluster_name = "${var.environment}-${var.msk_cluster_name}"
}

locals {
  kafka_topics = {
    fanProfile         = "event.resonanceEngine.fanProfile"
    fanTopArtists      = "event.resonanceEngine.fanTopArtists"
    fanTopTracks       = "event.resonanceEngine.fanTopTracks"
    fanRecentlyPlayed  = "event.resonanceEngine.fanRecentlyPlayed"
    fanPlaylists       = "event.resonanceEngine.fanPlaylists"
    fanSavedAlbums     = "event.resonanceEngine.fanSavedAlbums"
    fanSavedTracks     = "event.resonanceEngine.fanSavedTracks"
    fanFollowedArtists = "event.resonanceEngine.fanFollowedArtists"
  }
}

module "ows_service_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.8.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family

  desired_task_count                       = 2
  minimum_capacity                         = 2
  maximum_capacity                         = 4
  task_cpu                                 = 1024
  task_memory                              = 2048
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_private_subnet_ids

  splitio_enabled                = false
  ows_machine_to_machine_enabled = false

  iam_managed_policy_attachments = [
    aws_iam_policy.dsql_admin.arn,
    aws_iam_policy.encryption_keys_read_policy.arn,
    aws_iam_policy.dsp_secrets_read_policy.arn,
    aws_iam_policy.fan_collect_sqs_send_policy.arn,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      SENTRY_DSN = module.sentry.sentry_key_dsn_public_output
    },
    {
      DSQL_ENDPOINT = local.dsql_endpoint
    },
    {
      DSQL_TOKEN_EXPIRES_IN = local.dsql_token_expires_in_s
    },
    {
      REDIS_HOST = module.redis_elasticache.redis_primary_endpoint_address
    },
    {
      ENCRYPTION_KEYS_SECRET_NAME = local.encryption_keys_secret_name
    },
    {
      KAFKA_BOOTSTRAP_SERVERS = data.aws_msk_cluster.kafka_fansifter.bootstrap_brokers_tls
    },
    {
      KAFKA_TOPIC_FAN_PROFILE = local.kafka_topics.fanProfile
    },
    {
      KAFKA_TOPIC_FAN_TOP_ARTISTS = local.kafka_topics.fanTopArtists
    },
    {
      KAFKA_TOPIC_FAN_TOP_TRACKS = local.kafka_topics.fanTopTracks
    },
    {
      KAFKA_TOPIC_FAN_RECENTLY_PLAYED = local.kafka_topics.fanRecentlyPlayed
    },
    {
      KAFKA_TOPIC_FAN_PLAYLISTS = local.kafka_topics.fanPlaylists
    },
    {
      KAFKA_TOPIC_FAN_SAVED_ALBUMS = local.kafka_topics.fanSavedAlbums
    },
    {
      KAFKA_TOPIC_FAN_SAVED_TRACKS = local.kafka_topics.fanSavedTracks
    },
    {
      KAFKA_TOPIC_FAN_FOLLOWED_ARTISTS = local.kafka_topics.fanFollowedArtists
    },
    {
      SPOTIFY_SONGWHIP_CLIENT_ID = var.spotify_songwhip_client_id
    },
    {
      SPOTIFY_SONGWHIP_CLIENT_SECRET_NAME = local.spotify_songwhip_client_secret_name
    },
    {
      SQS_FAN_COLLECT_SPOTIFY_SONGWHIP_QUEUE_URL = module.sqs_fan_collect["spotify-songwhip"].queue_url
    },
    {
      SPOTIFY_SMF_SME_CLIENT_ID = var.spotify_smf_sme_client_id
    },
    {
      SPOTIFY_SMF_SME_CLIENT_SECRET_NAME = local.spotify_smf_sme_client_secret_name
    },
    {
      SQS_FAN_COLLECT_SPOTIFY_SMF_SME_QUEUE_URL = module.sqs_fan_collect["spotify-smf-sme"].queue_url
    },
    {
      SPOTIFY_SMF_ORCH_CLIENT_ID = var.spotify_smf_orch_client_id
    },
    {
      SPOTIFY_SMF_ORCH_CLIENT_SECRET_NAME = local.spotify_smf_orch_client_secret_name
    },
    {
      SQS_FAN_COLLECT_SPOTIFY_SMF_ORCH_QUEUE_URL = module.sqs_fan_collect["spotify-smf-orch"].queue_url
    },
    {
      SQS_FAN_COLLECT_DEEZER_SONGWHIP_QUEUE_URL = module.sqs_fan_collect["deezer-songwhip"].queue_url
    },
    {
      FAN_COLLECT_WORKER_TIMEOUT_S = var.fan_collect_worker_timeout_s
    },
    {
      FAN_FANOUT_WINDOW_S = var.fan_fanout_window_s
    },
    {
      AUTH0_DOMAIN = var.auth0_domain
    },
    {
      AUTH0_CLIENT_ID = var.auth0_client_id
    },
    {
      AUTH0_AUDIENCE = var.auth0_audience
    },
    {
      AUTH0_CALLBACK_URL = var.auth0_callback_url
    },
    {
      AUTH0_LOGOUT_REDIRECT = var.auth0_logout_redirect
    },
  ]

  secrets = [
    {
      AUTH0_CLIENT_SECRET = local.auth0_client_secret_name
    },
  ]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.7"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.application_family]

  service_cpu_monitor_evaluation_function = "avg"
  service_cpu_time_window                 = "last_10m"
  service_4xx_monitor_enabled             = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}

module "sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  application_family = var.application_family
}

module "redis_elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"

  providers = {
    aws.dns = aws
  }

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.id

  cache_engine               = "redis"
  redis_engine_version       = "7.0"
  cache_parameter_group_name = "default.redis7"
  cache_node_type            = "cache.t4g.small"
  cache_node_count           = 1
  cache_subnet_group_name    = "${var.environment}-elasticache-subnet-group"
}