module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/streamlit-creative-generator-poc/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "${var.environment}-fansifter.theorchard.io"
}

data "aws_route53_zone" "networking_route53_zone" {
  provider = aws.networking
  name     = "theorchard.io"
}

data "aws_acm_certificate" "certificate" {
  domain   = "*.${var.environment}-fansifter.theorchard.io"
  statuses = ["ISSUED"]
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.short_service_name
  secret_name        = each.value
}

# fargate environment
module "streamlit_service_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.8.1"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.short_service_name
  aws_region         = var.aws_region
  application_family = var.application_family
  non_ecr_image      = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${var.service_name}:latest"

  desired_task_count                       = 1
  minimum_capacity                         = 1
  maximum_capacity                         = 1
  task_cpu                                 = 1024
  task_memory                              = 2048
  task_type                                = "web_service"
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_private_subnet_ids
  health_check_path                        = "/_stcore/health"

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      POSTGRES_HOST = module.postgres_rds.rds_cluster_endpoint
    },
    {
      POSTGRES_NAME = module.postgres_rds.rds_cluster_database_name
    },
    {
      POSTGRES_PORT = module.postgres_rds.rds_cluster_port
    },
    {
      POSTGRES_USER = var.postgres_user
    },
    {
      ASSETS_BUCKET_NAME = module.assets_s3_bucket.s3_bucket_name_output
    },
    {
      ASSETS_CDN_DOMAIN = local.assets_cloudfront_domain
    }
  ]

  secrets = [
    {
      POSTGRES_PASSWORD = "${var.environment}/${var.short_service_name}/RDS_USER_PASSWORD"
    },
    {
      OPUS_CLIP_API_TOKEN = "${var.environment}/${var.short_service_name}/OPUS_CLIP_API_TOKEN"
    }
  ]
  iam_managed_policy_attachments = [
    aws_iam_policy.assets_s3_rw_policy.arn
  ]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.7"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.short_service_name
  application_family = var.application_family
  teams              = [var.application_family]

  service_4xx_monitor_enabled = false

  service_cpu_monitor_evaluation_function = "avg"
  service_cpu_time_window                 = "last_10m"

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter-alerts"
}