locals {
  preexisting_policies = toset([
    "${var.environment}-${var.application_family}-secrets-services-ro",
    "${var.environment}-${var.application_family}-s3_env_ro",
  ])
}

data "aws_ecr_repository" "lambda" {
  name = "${var.application_family}/${var.service_name}"
}

data "aws_iam_policy" "policies" {
  for_each = local.preexisting_policies
  name     = each.value
}

data "aws_secretsmanager_secret" "dd_api_key" {
  name = "${var.application_family}/${var.environment}/common/DD_API_KEY"
}

data "aws_vpc" "main" {
  tags = {
    Name = "${var.environment}-${var.application_family}-vpc"
  }
}

data "aws_subnets" "private" {
  filter {
    name   = "vpc-id"
    values = [data.aws_vpc.main.id]
  }

  tags = {
    Name = "${var.environment}-${var.application_family}-subnet-private-0*"
  }
}

data "aws_security_group" "lambda" {
  tags = {
    Name = "${var.environment}-${var.application_family}-sg-lambda"
  }
}

data "aws_kms_key" "secrets_general_key" {
  key_id = "alias/${var.environment}/${var.application_family}/secrets_general"
}