data "aws_cloudfront_response_headers_policy" "response_headers_policy" {
  name = "Managed-SimpleCORS"
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-orcd-waf-block"
  scope = "CLOUDFRONT"
}

resource "aws_cloudfront_distribution" "code_push_server_cdn" {
  # checkov:skip=CKV2_AWS_47:Ensure AWS CloudFront attached WAFv2 WebACL is configured with AMR for Log4j Vulnerability
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled
  enabled             = true
  is_ipv6_enabled     = false
  comment             = "Distribution for Code Push Server Bundles"
  price_class         = "PriceClass_All"
  http_version        = "http2"
  aliases             = ["${var.environment}-${var.service_name}-cdn.${var.route53_hosted_zone}"]
  default_root_object = "index.html"
  web_acl_id          = data.aws_wafv2_web_acl.waf.arn

  origin_group {
    origin_id = var.s3_origin_group_name

    failover_criteria {
      status_codes = var.failover_criteria_status_codes
    }

    member {
      origin_id = "S3-${module.s3_code_push_server_bucket.s3_bucket_name_output}"
    }

    member {
      origin_id = "S3-${data.aws_s3_bucket.s3_code_push_server_failover_bucket.bucket}"
    }
  }

  origin {
    domain_name              = module.s3_code_push_server_bucket.s3_bucket_domain_name_output
    origin_id                = "S3-${module.s3_code_push_server_bucket.s3_bucket_name_output}"
    origin_access_control_id = aws_cloudfront_origin_access_control.s3_code_push_server_bucket_origin_access_control.id
  }

  origin {
    domain_name              = data.aws_s3_bucket.s3_code_push_server_failover_bucket.bucket_domain_name
    origin_id                = "S3-${data.aws_s3_bucket.s3_code_push_server_failover_bucket.bucket}"
    origin_access_control_id = aws_cloudfront_origin_access_control.s3_code_push_server_bucket_origin_access_control.id
  }

  default_cache_behavior {
    viewer_protocol_policy = "https-only"
    compress               = true
    allowed_methods        = ["GET", "HEAD", "OPTIONS"]
    cached_methods         = ["GET", "HEAD"]

    response_headers_policy_id = data.aws_cloudfront_response_headers_policy.response_headers_policy.id

    target_origin_id = var.s3_origin_group_name
    min_ttl          = 0
    default_ttl      = 86400
    max_ttl          = 31536000

    forwarded_values {
      query_string = false

      cookies {
        forward = "none"
      }
      headers = [
        "Origin",
        "Access-Control-Request-Headers",
        "Access-Control-Request-Method",
      ]
    }
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  logging_config {
    include_cookies = false
    bucket          = var.cloudfront_logging_bucket
    prefix          = "${data.aws_caller_identity.current.account_id}/${var.environment}/${var.service_name}/"
  }

  viewer_certificate {
    acm_certificate_arn      = data.aws_acm_certificate.qa_mobile_code_push_pdestorage_com.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = "TLSv1.2_2021"
  }
}

resource "aws_cloudfront_origin_access_control" "s3_code_push_server_bucket_origin_access_control" {
  name                              = "${var.environment}-${var.service_name}"
  description                       = "${var.environment}-${var.service_name} Policy"
  origin_access_control_origin_type = "s3"
  signing_behavior                  = "always"
  signing_protocol                  = "sigv4"
}

resource "aws_route53_record" "route53_record" {
  name    = "${var.environment}-${var.service_name}-cdn"
  zone_id = data.aws_route53_zone.route53_zone.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.code_push_server_cdn.domain_name]
}