module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = "devops"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  profile = "networking"
  alias   = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}


# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-mobile-code-push-terraform-state"
    key     = "qa/qa-mobile-code-push.pdestorage.com/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_route53_zone" "subdomain" {
  # checkov:skip=CKV2_AWS_38: DNSSEC must be first implemented in the parent zone
  name = var.domain_name
}

data "aws_route53_zone" "main_domain_networking" {
  provider = aws.networking
  name     = "pdestorage.com"
}

resource "aws_route53_record" "subdomain_ns_networking" {
  provider = aws.networking
  zone_id  = data.aws_route53_zone.main_domain_networking.id
  name     = var.domain_name
  type     = "NS"
  ttl      = "172800"
  records  = aws_route53_zone.subdomain.name_servers
}

resource "aws_cloudwatch_log_group" "route53_query_log_group" {
  # checkov:skip=CKV_AWS_338: Ensure CloudWatch log groups retains logs for at least 1 year
  name              = "/aws/route53/${aws_route53_zone.subdomain.name}"
  retention_in_days = 30
}

data "aws_iam_policy_document" "route53_query_logging_policy" {
  statement {
    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]

    resources = ["${aws_cloudwatch_log_group.route53_query_log_group.arn}:*"]

    principals {
      type        = "Service"
      identifiers = ["route53.amazonaws.com"]
    }
  }
}

resource "aws_cloudwatch_log_resource_policy" "route53_query_logging_policy" {
  policy_document = data.aws_iam_policy_document.route53_query_logging_policy.json
  policy_name     = "Route53-query-logging-policy"
}

resource "aws_route53_query_log" "query_log" {
  depends_on = [aws_cloudwatch_log_resource_policy.route53_query_logging_policy]

  cloudwatch_log_group_arn = aws_cloudwatch_log_group.route53_query_log_group.arn
  zone_id                  = aws_route53_zone.subdomain.zone_id
}