locals {
  output_bucket_arn = "arn:aws:s3:::${var.output_bucket_name}"
  input_bucket_arn  = "arn:aws:s3:::${var.input_bucket_name}"
}

data "aws_caller_identity" "current" {
}

data "aws_iam_policy_document" "elastictranscoder_execution_iam_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:ListBucket",
    ]

    resources = [
      local.input_bucket_arn,
      local.output_bucket_arn,
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:Get*",
    ]

    resources = [
      "${local.input_bucket_arn}/*",
      "${local.output_bucket_arn}/*",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:Put*",
      "s3:*MultipartUpload*",
    ]

    resources = [
      "${local.output_bucket_arn}/*",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "sns:Publish",
    ]

    resources = [
      var.notifications_sns_topic_arn,
    ]
  }

  statement {
    effect = "Deny"

    actions = [
      "s3:*Policy*",
      "s3:*Delete*",
      "sns:*Remove*",
    ]

    resources = [
      local.input_bucket_arn,
      local.output_bucket_arn,
    ]
  }
}

data "aws_iam_policy_document" "assume_elastictranscoder_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["elastictranscoder.amazonaws.com"]
    }
  }
}

resource "aws_iam_role" "elastictranscoder_role" {
  name               = "${var.environment}-asset-transcoder-elastictranscoder-${var.pipeline_name}"
  assume_role_policy = data.aws_iam_policy_document.assume_elastictranscoder_role.json
}

resource "aws_iam_policy" "elastictranscoder_policy" {
  name   = "${var.environment}-asset-transcoder-elastictranscoder-${var.pipeline_name}"
  policy = data.aws_iam_policy_document.elastictranscoder_execution_iam_policy.json
}

resource "aws_iam_role_policy_attachment" "elastictranscoder_policy_attachment" {
  role       = aws_iam_role.elastictranscoder_role.name
  policy_arn = aws_iam_policy.elastictranscoder_policy.arn
}

resource "aws_elastictranscoder_pipeline" "asset_transcoder_elastictranscoder" {
  input_bucket = var.input_bucket_name
  name         = "${var.environment}-${var.pipeline_name}"
  role         = aws_iam_role.elastictranscoder_role.arn

  content_config {
    bucket        = var.output_bucket_name
    storage_class = "Standard"
  }

  thumbnail_config {
    bucket        = var.output_bucket_name
    storage_class = "Standard"
  }

  notifications {
    error       = var.notifications_sns_topic_arn
    completed   = var.notifications_sns_topic_arn
    warning     = var.notifications_sns_topic_arn
    progressing = ""
  }
}