# Lambda function for generation of waveform output file
data "aws_iam_policy_document" "elastictranscoder_create_job_lambda_policy_document" {
  statement {
    sid    = ""
    effect = "Allow"
    resources = [
      "arn:aws:elastictranscoder:us-east-1:${local.account_id}:pipeline/*",
      "arn:aws:elastictranscoder:us-east-1:${local.account_id}:job/*",
      "arn:aws:elastictranscoder:us-east-1:${local.account_id}:preset/*"
    ]

    actions = [
      "elastictranscoder:CreateJob"
    ]
  }
}

resource "aws_iam_policy" "elastictranscoder_create_job_lambda_policy" {
  name        = "${var.environment}-elastictranscoder-create-job-lambda-policy"
  description = "Create Elastic Transcoder jobs"
  policy      = data.aws_iam_policy_document.elastictranscoder_create_job_lambda_policy_document.json
}

module "audio_waveform_lambda" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"

  application_family  = var.application_family
  environment         = var.environment
  lambda_name         = "asset-transcoder-audio-waveform"
  use_container_image = true
  lambda_description  = "Generates audio waveform using audiowaveform binary"

  lambda_function_environment_variables = merge({
    Environment                  = var.environment
    SNS_FINAL_STATUS_TOPIC_ARN   = module.sns_final_status.proxied_sns_arn
    SNS_GENERAL_STATUS_TOPIC_ARN = module.sns_general_status.proxied_sns_arn
    LOGGER_DSN                   = "udp://${var.environment}-fluentd-applications-udp.theorchard.io:5160"
  }, var.lambda_additional_environment_variables)

  lambda_function_timeout                        = var.audio_waveform_lambda_execution_time
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_memory_size                    = var.audio_waveform_lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_policy_file_enabled                        = false
  iam_managed_policy_attachments = [
    aws_iam_policy.common_lambda_policy.arn,
    aws_iam_policy.final_status_publish_lambda_policy.arn,
    var.output_buckets_readwrite_policy_arn,
    aws_iam_policy.elastictranscoder_create_job_lambda_policy.arn
  ]
}