provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "networking-orcd-terraform-state"
    key     = "networking/networking.theorchard.io/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = "theorchard.io"
  private_zone = false
}

resource "aws_route53_zone" "networking" {
  # checkov:skip=CKV2_AWS_38: DNSSEC must be first implemented in the parent zone
  name = var.domain_name
}

resource "aws_route53_record" "dev_theorchard_io_subdomain" {
  name    = var.domain_name
  ttl     = 172800
  type    = "NS"
  zone_id = data.aws_route53_zone.domain.zone_id

  records = var.nameservers
}

resource "aws_cloudwatch_log_group" "route53_query_log_group" {
  name              = "/aws/route53/${aws_route53_zone.networking.name}"
  retention_in_days = 365
}

data "aws_iam_policy_document" "route53_query_logging_policy" {
  statement {
    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]

    resources = ["${aws_cloudwatch_log_group.route53_query_log_group.arn}:*"]

    principals {
      type        = "Service"
      identifiers = ["route53.amazonaws.com"]
    }
  }
}

resource "aws_cloudwatch_log_resource_policy" "route53_query_logging_policy" {
  policy_document = data.aws_iam_policy_document.route53_query_logging_policy.json
  policy_name     = "Route53-query-logging-policy-${replace(var.domain_name, ".", "_")}"
}

resource "aws_route53_query_log" "query_log" {
  depends_on = [aws_cloudwatch_log_resource_policy.route53_query_logging_policy]

  cloudwatch_log_group_arn = aws_cloudwatch_log_group.route53_query_log_group.arn
  zone_id                  = aws_route53_zone.networking.zone_id
}

resource "aws_acm_certificate" "tls_cert" {
  # checkov:skip=CKV2_AWS_71: Ensure AWS ACM Certificate domain name does not include wildcards
  domain_name               = "*.${aws_route53_zone.networking.name}"
  subject_alternative_names = [aws_route53_zone.networking.name]
  validation_method         = "DNS"

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  tags = {
    environment = var.environment
    terraformed = "true"
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_route53_record" "dns_validation_record" {
  for_each = {
    for validation_object in aws_acm_certificate.tls_cert.domain_validation_options : validation_object.domain_name => {
      name   = validation_object.resource_record_name
      record = validation_object.resource_record_value
      type   = validation_object.resource_record_type
    }
  }

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 60
  type            = each.value.type
  zone_id         = aws_route53_zone.networking.zone_id
}

resource "aws_acm_certificate_validation" "certificate_validation" {
  certificate_arn         = aws_acm_certificate.tls_cert.arn
  validation_record_fqdns = [for record in aws_route53_record.dns_validation_record : record.fqdn]
}