module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "networking-orcd-terraform-state"
    key     = "networking/smedxnet/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_route53_zone" "smedx_net" {
  # checkov:skip=CKV2_AWS_38: DNSSEC must be first implemented in the parent zone
  name = var.domain_name
}

resource "aws_cloudwatch_log_group" "route53_query_log_group" {
  name              = "/aws/route53/${aws_route53_zone.smedx_net.name}"
  retention_in_days = 365
}

data "aws_iam_policy_document" "route53_query_logging_policy" {
  statement {
    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]

    resources = ["${aws_cloudwatch_log_group.route53_query_log_group.arn}:*"]

    principals {
      type        = "Service"
      identifiers = ["route53.amazonaws.com"]
    }
  }
}

resource "aws_cloudwatch_log_resource_policy" "route53_query_logging_policy" {
  policy_document = data.aws_iam_policy_document.route53_query_logging_policy.json
  policy_name     = "Route53-query-logging-policy-${replace(var.domain_name, ".", "_")}"
}

resource "aws_route53_query_log" "query_log" {
  depends_on = [aws_cloudwatch_log_resource_policy.route53_query_logging_policy]

  cloudwatch_log_group_arn = aws_cloudwatch_log_group.route53_query_log_group.arn
  zone_id                  = aws_route53_zone.smedx_net.zone_id
}