module "pde_gsirt_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.2.6"

  bucket_name        = "pde-gsirt"
  env                = var.environment
  application_family = var.application_family
  bucket_policy_overrides = [
    data.aws_iam_policy_document.custom_bucket_policy.json
  ]

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }


  lifecycle_rules_abort_incomplete_multipart_upload_days = [
    {
      prefix  = ""
      enabled = true
      days    = 7
    }
  ]
}

data "aws_iam_policy_document" "pde_gsirt_s3_read_write_only_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:CreateMultipartUpload",
      "s3:UploadPart",
      "s3:AbortMultipartUpload",
      "s3:CompleteMultipartUpload",
    ]

    resources = [
      "${module.pde_gsirt_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "pde_gsirt_s3_read_write_only_policy" {
  name        = "S3-${module.pde_gsirt_bucket.s3_bucket_name_output}-RW"
  description = "Read Write access to ${module.pde_gsirt_bucket.s3_bucket_name_output} bucket"
  policy      = data.aws_iam_policy_document.pde_gsirt_s3_read_write_only_policy_document.json
}

# JIRA WIZ-2276 Receive object replication from SME GSIRT account
data "aws_iam_policy_document" "custom_bucket_policy" {
  statement {
    sid    = "DenyRequestsWithoutSSL"
    effect = "Deny"

    resources = [
      "${module.pde_gsirt_bucket.s3_bucket_arn_output}/*",
      "${module.pde_gsirt_bucket.s3_bucket_arn_output}",
    ]

    actions = [
      "s3:*"
    ]

    condition {
      test     = "Bool"
      variable = "aws:SecureTransport"
      values   = [
        "false"
      ]
    }

    principals {
      type        = "*"
      identifiers = ["*"]
    }
  }

  statement {
    sid    = "AllowReplicationActions"
    effect = "Allow"

    resources = [
      "${module.pde_gsirt_bucket.s3_bucket_arn_output}/*",
      "${module.pde_gsirt_bucket.s3_bucket_arn_output}",
    ]

    actions = [
      "s3:ReplicateObject",
      "s3:ReplicateDelete",
      "s3:PutBucketVersioning",
      "s3:ObjectOwnerOverrideToBucketOwner",
      "s3:List*",
      "s3:GetBucketVersioning",
    ]

    principals {
      type        = "AWS"
      identifiers = [
        "arn:aws:iam::${var.sme_gsirt_ioc_account_id}:role/service-role/${var.sme_gsirt_ioc_source_account_role}"
        ]
    }
  }

  statement {
    sid    = "DenyDestructiveActions"
    effect = "Deny"

    resources = [
      "arn:aws:s3:::prod-pde-gsirt/*",
      "arn:aws:s3:::prod-pde-gsirt",
    ]

    actions = [
      "s3:DeleteObject*",
      "s3:DeleteBucketPolicy",
      "s3:DeleteBucket",
    ]

    principals {
      type        = "*"
      identifiers = ["*"]
    }
  }
}