provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "networking-orcd-terraform-state"
    key     = "networking/iam/roles/generic-engineer-role/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = [
      "sts:AssumeRole"
    ]

    effect = "Allow"

    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::437795906767:root"]
    }

    condition {
      test     = "StringLike"
      values   = ["$${aws:username}"]
      variable = "sts:RoleSessionName"
    }

    condition {
      test     = "Bool"
      values   = ["true"]
      variable = "aws:MultiFactorAuthPresent"
    }
  }
}

data "aws_iam_policy_document" "route53_read_access" {
  statement {
    actions = [
      "route53:ListResourceRecordSets",
      "route53:ListHostedZones",
      "route53:GetHostedZone"
    ]

    effect = "Allow"

    resources = [
      "*"
    ]
  }
}

resource "aws_iam_policy" "route53_read_access" {
  policy = data.aws_iam_policy_document.route53_read_access.json
  name   = "Route53-${var.environment}-shared-RO"

  tags = {
    "terraformed" = "true"
  }
}

resource "aws_iam_role" "generic_engineer_role" {
  name                 = var.role_name
  max_session_duration = 43200
  assume_role_policy   = data.aws_iam_policy_document.assume_role_policy.json

  tags = {
    "terraformed" = "true"
  }
}

resource "aws_iam_role_policy_attachment" "generic_engineer_role_route53_read_access" {
  policy_arn = aws_iam_policy.route53_read_access.arn
  role       = aws_iam_role.generic_engineer_role.name
}