module "lambda_ioc_sanitize" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"

  environment                    = var.environment
  lambda_name                    = "lambda-${var.service_name}-sanitize"
  application_family             = var.application_family
  lambda_description             = "Sanitize domain and ip blocks; generates domain, ip, url files"
  use_container_image            = true
  datadog_advanced_enabled       = true
  vpc_enabled                    = true
  vpc_id                         = module.vpc_info.vpc_id
  vpc_subnet_ids                 = module.vpc_info.default_private_subnet_ids
  lambda_function_timeout        = 60
  splitio_enabled                = false
  ows_machine_to_machine_enabled = false
  iam_managed_policy_attachments = [
    aws_iam_policy.s3_policy.arn
  ]

  lambda_function_environment_variables = {
    Environment                     = var.environment
    SERVICE_NAME                    = "lambda-${var.service_name}-sanitize"
    GSIRT_S3_DROP_BUCKET            = "${var.environment}-pde-gsirt"
    GSIRT_S3_DROP_BUCKET_ACCOUNT_ID = data.aws_caller_identity.current.account_id
    GSIRT_S3_DROP_FOLDER            = "pde"
    GSIRT_S3_SANITIZED_FOLDER       = "sanitized"
    GSIRT_S3_DROP_DOMAIN_FILE       = "ioc-block-domain.txt"
    GSIRT_S3_DROP_IP_FILE           = "ioc-block-ips.txt"
  }
}

# Policy for lambda to download gsirt ioc files, sanitize them, and upload them to the sanitized folder.
data "aws_iam_policy_document" "s3_policy_document" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject*",
      "s3:ListBucket",
    ]
    resources = [
      "arn:aws:s3:::${data.aws_s3_bucket.pde_gsirt_bucket.id}/pde/*"
    ]
  }
  statement {
    actions = [
      "s3:PutObject"
    ]
    resources = [
      "arn:aws:s3:::${data.aws_s3_bucket.pde_gsirt_bucket.id}/sanitized/*"
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      data.aws_s3_bucket.pde_gsirt_bucket.arn
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListAllMyBuckets"
    ]

    resources = [
      "*"
    ]
  }
}

resource "aws_iam_policy" "s3_policy" {
  policy = data.aws_iam_policy_document.s3_policy_document.json
  name   = "S3-${var.environment}-${var.service_name}-policy"
}