module "lambda_ioc_update_dns_firewall" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"

  environment                    = var.environment
  lambda_name                    = "lambda-${var.service_name}-update-dns-firewall"
  application_family             = var.application_family
  lambda_description             = "Updates dns firewall from domain list in S3 object."
  use_container_image            = true
  datadog_advanced_enabled       = true
  vpc_id                         = module.vpc_info.vpc_id
  vpc_subnet_ids                 = module.vpc_info.default_private_subnet_ids
  lambda_function_timeout        = 60
  splitio_enabled                = false
  ows_machine_to_machine_enabled = false
  iam_managed_policy_attachments = [
    aws_iam_policy.pde_gsirt_ro_sanitized.arn
  ]

  lambda_function_environment_variables = {
    Environment    = var.environment
    SERVICE_NAME   = "lambda-${var.service_name}-update-dns-firewall"
    DOMAIN_LIST_ID = var.domain_list_id
  }
}

data "aws_iam_policy_document" "update_dns_firewall_policy" {
  statement {
    effect = "Allow"
    actions = [
      "route53resolver:GetFirewallDomainList",
      "route53resolver:UpdateFirewallDomains"
    ]
    resources = ["arn:aws:route53resolver:${var.aws_region}:${data.aws_caller_identity.current.account_id}:firewall-domain-list/${var.domain_list_id}"]
  }
  statement {
    effect = "Allow"
    actions = [
      "route53resolver:ListFirewallDomains",
      "route53resolver:ListFirewallDomainLists",
    ]
    resources = ["*"]
  }
}

resource "aws_iam_role_policy" "update_dns_firewall_policy" {
  role   = module.lambda_ioc_update_dns_firewall.lambda_role_id
  policy = data.aws_iam_policy_document.update_dns_firewall_policy.json
  name   = "lambda-${var.service_name}-update-dns-firewall-policy"
}