module "lambda_ioc_update_waf_ipsets" {
  source = "git@github.com:theorchard/terraform-lambda.git?ref=4.1.0"

  environment                    = var.environment
  lambda_name                    = "lambda-${var.service_name}-update-waf-ipsets"
  application_family             = var.application_family
  lambda_description             = "Updates waf ip sets via given IAM role."
  use_container_image            = true
  datadog_advanced_enabled       = true
  vpc_id                         = module.vpc_info.vpc_id
  vpc_subnet_ids                 = module.vpc_info.default_private_subnet_ids
  lambda_function_timeout        = 60
  splitio_enabled                = false
  ows_machine_to_machine_enabled = false
  iam_managed_policy_attachments = [
    aws_iam_policy.pde_gsirt_ro_sanitized.arn
  ]

  lambda_function_environment_variables = {
    Environment         = var.environment
    SERVICE_NAME        = "lambda-${var.service_name}-update-waf-ipsets"
    DEFAULT_ROLE_NAME   = "${var.environment}-gsirt-ioc-ip-set-updater-role"
    DEFAULT_IP_SET_NAME = "${var.environment}-gsirt-ioc-ip-set-ipv4"
    DEFAULT_EXTERNAL_ID = var.external_id
  }
}

data "aws_iam_policy_document" "update_waf_ipsets_assume_policy" {
  statement {
    effect = "Allow"
    actions = [
      "sts:AssumeRole"
    ]
    # Only allow a test role for QA
    # resources = formatlist("arn:aws:iam::%s:role/gsirt-ioc-ip-set-updater-role", module.aws_accounts.account_ids)
    resources = ["arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/qa-gsirt-ioc-ip-set-updater-role"]
  }
}

resource "aws_iam_role_policy" "update_waf_ipsets_assume_policy" {
  role   = module.lambda_ioc_update_waf_ipsets.lambda_role_id
  policy = data.aws_iam_policy_document.update_waf_ipsets_assume_policy.json
  name   = "STS-lambda-${var.service_name}-update-waf-ipsets-assume-role-policy"
}