module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "networking-orcd-terraform-state"
    key     = "networking/qa/ioc-block-list/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.networking.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "networking.theorchard.io"
}

data "aws_s3_bucket" "pde_gsirt_bucket" {
  bucket = "qa-pde-gsirt"
}

data "aws_iam_policy" "pde_gsirt_ro_sanitized" {
  name = "S3-${data.aws_s3_bucket.pde_gsirt_bucket.id}-sanitized-RO-policy"
}

module "ioc_block_list_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.2"

  providers = {
    aws.dns = aws
  }

  environment                   = var.environment
  service_name                  = var.service_name
  application_family            = var.application_family
  aws_region                    = var.region
  non_ecr_image                 = "086679231553.dkr.ecr.us-east-1.amazonaws.com/ioc-block-list:latest"
  container_port                = "80"
  task_type                     = "web_service"
  desired_task_count            = 2
  task_cpu                      = 512
  task_memory                   = 1024
  maximum_capacity              = 2
  minimum_capacity              = 2
  health_check_path             = "/"
  route53_zone_id               = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  custom_waf_arn                = module.custom_waf.waf_blocking_arn_output

  https_listener_public_allow_cidr_blocks = [
    "10.20.0.120/32",
    "10.20.0.121/32",
    "192.168.32.0/24",
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    data.aws_iam_policy.pde_gsirt_ro_sanitized.arn
  ]

  environment_variables = [
    {
      S3_BUCKET = data.aws_s3_bucket.pde_gsirt_bucket.id
    },
  ]

  auth_issuers = { "networking" : "dummy" }

  depends_on = [module.custom_waf]
}

module "ioc_block_list_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.4"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = "devops"
  notification_endpoints            = "@slack-devops-internal-alerts"
  escalation_notification_endpoints = "@slack-devops-internal-alerts"

  critical_number_5xx          = 20
  critical_recovery_number_5xx = 15
  warning_number_5xx           = 10
  warning_recovery_number_5xx  = 5
}