module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.application_family
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-permissions-platform-terraform-state"
    key     = "qa/auth0-m2m-config/integration-tests/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "m2m_auth0_client_credentials" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
}

# This role is allowed to perform auth0-m2m-config operations
# Jenkins deploy agent is already allowed to assume this role
data "aws_iam_role" "qa_auth0_m2m_config_task_role" {
  name = "${var.environment}-auth0-m2m-config-task-role"
}

# Additionally grant it ability to view/edit the m2m_auth0_client_credentials
data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    actions = [
      "secretsmanager:GetSecretValue",
      "secretsmanager:PutSecretValue",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/M2M_AUTH0_CLIENT_CREDENTIALS",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/M2M_AUTH0_CLIENT_CREDENTIALS*",
    ]
  }
}

resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-access-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# Attach SecretsManager access policy to qa-auth0-m2m-config-task-role role.
resource "aws_iam_role_policy_attachment" "secret_manager_policy_attachment" {
  role       = data.aws_iam_role.qa_auth0_m2m_config_task_role.id
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}