data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

data "aws_iam_policy_document" "sfn_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
        "events.amazonaws.com",
      ]
    }
  }
}

data "aws_iam_policy_document" "invoke_lambda_policy" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_post_restore.lambda_arn,
      module.lambda_start_refresh.lambda_arn,
    ]
  }
}

data "aws_iam_policy_document" "publish_sns_notification_policy" {
  statement {
    actions = [
      "sns:Publish",
    ]

    resources = [
      module.sfn_notifications.topic_arn,
    ]
  }
}

data "aws_iam_policy_document" "sfn_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]
  }

  statement {
    effect = "Allow"
    resources = [
      "*",
    ]

    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}

# Step Function state machine definition template
data "template_file" "sfn_definition" {
  template = file("${path.module}/sfn-dynamodb-refresh.json")

  vars = {
    lambda_post_restore_arn  = module.lambda_post_restore.lambda_arn
    lambda_start_refresh_arn = module.lambda_start_refresh.lambda_arn

    pdp_backfill_task_definition_arn = data.aws_ecs_task_definition.pdp_backfill_task_definition.arn_without_revision
    pdp_backfill_cluster_arn         = data.aws_ecs_cluster.pdp_backfill_cluster.arn
    pdp_backfill_private_subnets     = jsonencode(module.vpc_info.default_private_subnet_ids)
    pdp_backfill_task_security_group = data.aws_security_group.pdp_backfill_task_sg.id
    pdp_backfill_container_name      = local.container_name
    backfill_bucket                  = var.refresh_backfill_bucket
    manifest_file_key                = var.refresh_backfill_manifest_file_key
    sns_notification_topic_arn       = module.sfn_notifications.topic_arn
  }
}

resource "aws_iam_role" "sfn_dynamodb_refresh_role" {
  name               = "${var.environment}-${var.service_name}-sfn-role"
  description        = "${var.environment}-${var.service_name}-sfn-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_assume_role_policy.json
}

resource "aws_iam_role_policy" "sfn_dynamodb_refresh_invoke_lambda_role_policy" {
  name   = "${var.environment}-${var.service_name}-invoke-lambda-and-fargate-policy"
  role   = aws_iam_role.sfn_dynamodb_refresh_role.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy.json
}

resource "aws_iam_role_policy" "sfn_dynamodb_refresh_publish_sns_notification_role_policy" {
  name   = "${var.environment}-${var.service_name}-publish-sns-notification-policy"
  role   = aws_iam_role.sfn_dynamodb_refresh_role.id
  policy = data.aws_iam_policy_document.publish_sns_notification_policy.json
}

resource "aws_iam_role_policy" "sfn_dynamodb_refresh_log_event_role_policy" {
  name   = "${var.environment}-${var.service_name}-sfn-log-policy"
  role   = aws_iam_role.sfn_dynamodb_refresh_role.id
  policy = data.aws_iam_policy_document.sfn_log_event_policy_document.json
}

resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name              = "${var.environment}-${var.service_name}-sfn-log-group"
  retention_in_days = 365
  tags              = local.tags
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_lambda_function_log_filter" {
  name            = "${var.environment}-${var.service_name}-sfn-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

# Step Function (SFN) definition for marketing ingest
resource "aws_sfn_state_machine" "sfn_dynamodb_refresh" {
  name       = "${var.environment}-dynamodb-refresh-sfn"
  role_arn   = aws_iam_role.sfn_dynamodb_refresh_role.arn
  definition = data.template_file.sfn_definition.rendered
  tags       = local.tags
  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }
}