provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-permissions-platform-terraform-state"
    key     = "qa/elasticsearch/indices/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_opensearch_domain" "pp_opensearch" {
  domain_name = "${var.environment}-pp-es"
}

# If you need to run this locally, add a principal to this trust policy
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/cross-account-atlantis-role"
      ]
    }
  }
}

# Role exclusively used for creating Elasticsearch indices 
resource "aws_iam_role" "es_index_role" {
  name               = "${var.environment}-pp-es-index-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Set up provider with correct role to assume
provider "opensearch" {
  url                         = "https://${data.aws_opensearch_domain.pp_opensearch.endpoint}"
  healthcheck                 = false
  aws_assume_role_arn         = aws_iam_role.es_index_role.arn
  aws_assume_role_external_id = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/cross-account-atlantis-role"
}