# OpenSearch Sink connector dedicated
# to writing SME Labels to the sme_label.v* index

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = local.service_name
  team_name          = var.team_name
}

terraform {
  backend "s3" {
    bucket  = "qa-permissions-platform-terraform-state"
    key     = "qa/kafka-pp/connectors/sink/opensearch/sme_label/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_msk_cluster" "kafka_pp" {
  cluster_name = "${var.environment}-${var.msk_cluster_name}"
}

data "aws_opensearch_domain" "pp_opensearch" {
  domain_name = "${var.environment}-pp-es"
}

data "aws_iam_policy" "es_rw_policy" {
  name = "Elasticsearch-${var.environment}-pp-es-RW-policy"
}

module "connector_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  service_name       = local.service_name
  secret_name        = "OPENSEARCH_CREDENTIALS"
}

module "os_sink_fargate_environment_sme_label" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.0.0"
  providers = {
    aws.dns = aws.networking
  }
  environment                       = var.environment
  application_family                = var.application_family
  additional_tags                   = var.additional_tags
  service_name                      = local.service_name
  non_ecr_image                     = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${local.ecr_repo_name}:latest"
  aws_region                        = var.aws_region
  service_platform_version          = "1.4.0"
  desired_task_count                = 1
  minimum_capacity                  = 1
  maximum_capacity                  = 3
  task_cpu                          = 2048
  task_memory                       = 4096
  autoscaling_cpu_policy_enabled    = false
  autoscaling_memory_policy_enabled = false
  container_port                    = 8083
  health_check_grace_period_seconds = 300
  container_start_period_seconds    = 300
  blocking_waf_enabled              = true
  health_check_path                 = "/connectors/${var.environment}-${local.service_name}/status"
  web_service_health_check_command  = "[[ $(curl -s http://localhost:8083/connectors/${var.environment}-${local.service_name}/status | jq -r '.tasks[].state' | sort | uniq) == 'RUNNING' ]] || exit 1"
  vpc_id                            = module.vpc_info.vpc_id
  fargate_service_subnets           = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets             = module.vpc_info.default_private_subnet_ids
  propagate_tags                    = true

  iam_managed_policy_attachments = [
    data.aws_iam_policy.es_rw_policy.arn
  ]
  datadog_custom_image = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]
  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = data.aws_msk_cluster.kafka_pp.bootstrap_brokers_tls
    },
    {
      CONNECTOR_NAME = "${var.environment}-${local.service_name}"
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${local.service_name}"
    },
    {
      BATCH_SIZE = "1000" # connector's default: 2000
    },
    {
      FLUSH_TIMEOUT_MS = "400000" # connector's default: 180000
    },
    {
      READ_TIMEOUT_MS = "30000" # connector's default: 3000
    },
    {
      MAX_TASKS = "1" # qa
    },
    {
      OPENSEARCH_HOST = "https://${data.aws_opensearch_domain.pp_opensearch.endpoint}"
    },
    {
      OPENSEARCH_DOC_TYPE = "_doc"
    },
    {
      OPENSEARCH_KEY_IGNORE = "false"
    },
    {
      OPENSEARCH_SCHEMA_IGNORE = "true"
    },
    {
      KAFKA_TOPICS = join(",", [
        "cdc.musicGraph.smeLabel",
      ])
    },
    {
      SECRETS_MANAGER_OPENSEARCH_SECRET_NAME = "OPENSEARCH_CREDENTIALS"
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      TRANSFORMS_RENAMETOPIC_REPLACEMENT = "sme_label_write"
    },
    {
      TRANSFORMS_RENAMETOPIC_REGEX = ".*"
    },
    {
      TRANSFORMS_RENAMETOPIC_TYPE = "org.apache.kafka.connect.transforms.RegexRouter"
    },
    {
      TRANSFORMS = "renameTopic"
    },
    {
      WRITE_METHOD = "upsert"
    },
    {
      MAX_IN_FLIGHT_REQUESTS = "1"
    },
    {
      DLQ_TOPIC_NAME = var.dlq_topic_name
    },
    {
      DLQ_HEADERS_ENABLE = "true"
    },
    {
      DEBUG_MODE = "false"
    }
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.os_sink_fargate_environment_sme_label.fargate_security_group_id
  self              = true
  type              = "ingress"
}

data "aws_ec2_managed_prefix_list" "orchard_prod_private" {
  name = "prod-orcd-private-subnet-prefix-list"
}

# This rule will allow AKHQ to communicate with this kafka-connect service (LB)
resource "aws_security_group_rule" "allow_orchard_prod_private" {
  type              = "ingress"
  from_port         = 443
  to_port           = 443
  protocol          = "TCP"
  security_group_id = module.os_sink_fargate_environment_sme_label.fargate_load_balancer_security_group_id
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.orchard_prod_private.id
  ]
  depends_on = [module.os_sink_fargate_environment_sme_label]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.13.9"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = local.service_name
  application_family = var.application_family
  teams              = [var.application_family]
  additional_tags    = var.additional_tags
  connector_type     = "default_sink"

  notification_endpoints            = var.dd_notification_endpoints
  escalation_notification_endpoints = var.dd_escalation_notification_endpoints
  monitor_kafka_topics              = ["cdc.musicGraph.smeLabel"]
  monitor_kafka_topics_cluster_name = "${var.environment}-${var.msk_cluster_name}"

  healthy_tasks_monitor_enabled        = true
  service_cpu_monitor_enabled          = true
  error_monitor_enabled                = true
  dlq_topic_name                       = var.dlq_topic_name
  error_monitor_critical_number_errors = 5
}