provider "aws" {
  region = var.region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-permissions-platform-terraform-state"
    key     = "qa/lambda-auth0-m2m-token-secret-rotation/integration-test/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

#### CREATE INTEGRATION TEST LAMBDA FUNCTION ####
module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.0.0"

  environment = "qa" # Hardcode to qa because test isn't an environment
}

module "lambda" {
  source                  = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"
  lambda_name             = var.lambda_name
  lambda_description      = "Lambda to rotate Auth0 M2M token secret"
  lambda_function_timeout = 900 # 15 minutes
  environment             = var.environment
  application_family      = var.application_family

  lambda_function_memory_size                    = 512
  lambda_function_reserved_concurrent_executions = var.lambda_function_reserved_concurrent_executions

  vpc_enabled             = true
  vpc_id                  = module.vpc_info.vpc_id
  vpc_subnet_ids          = module.vpc_info.default_private_subnet_ids
  vpc_security_group_name = "qa-lambda-default-security-group" # Hardcode test isn't in the name of the sg
  use_container_image     = true

  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT        = var.environment
    AUTH0_URL          = var.auth0_url
    SENTRY_ENVIRONMENT = data.aws_caller_identity.current.account_id
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.secrets_manager_policy.arn,
  ]

  additional_tags = var.additional_tags

  # This is precisely the thing we are trying to eliminate
  # Let's not depend on it being here.
  ows_machine_to_machine_enabled = false

  # We don't have a splitio policy for the "test" environment
  # TODO: PP-820
  splitio_enabled = false

  # We don't have a datadog policy for the "test" environment
  # TODO: PP-821
  datadog_enabled = false
}

# Policy to get access to secrets and write to token secret
data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
    ]

    resources = [
      "arn:aws:secretsmanager:${var.region}:*:secret:${var.environment}/${var.machine_name}/M2M_AUTH0_CLIENT_CREDENTIALS",
      "arn:aws:secretsmanager:${var.region}:*:secret:${var.environment}/${var.machine_name}/M2M_AUTH0_CLIENT_CREDENTIALS*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.machine_name}/M2M_JWT_ACCESS_TOKEN",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.machine_name}/M2M_JWT_ACCESS_TOKEN*",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:PutSecretValue",
      "secretsmanager:UpdateSecretVersionStage",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.machine_name}/M2M_JWT_ACCESS_TOKEN",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.machine_name}/M2M_JWT_ACCESS_TOKEN*",
    ]
  }
}

resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.lambda_name}-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

resource "aws_lambda_permission" "allow_secrets_manager_invocation" {
  statement_id   = "SecretsManager-${module.lambda.lambda_name}-M2M_JWT_ACCESS_TOKEN"
  action         = "lambda:InvokeFunction"
  function_name  = "${module.lambda.lambda_name}"
  principal      = "secretsmanager.amazonaws.com"
  source_arn     = "arn:aws:secretsmanager:${var.region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/*/M2M_JWT_ACCESS_TOKEN*"
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry//?ref=4.1.2"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = ["qa"]
  platform           = "python"
}

#### ALLOW JENKINS TO ASSUME A ROLE WITH POLICIES THAT ARE REQUIRED
#### TO RUN THE INTEGRATION TESTS FOR LAMBDA-AUTH0-M2M-TOKEN-SECRET-ROTATION

# Running integration tests requires ability to GetSecretValue and RotateSecret
# Integration tests need to read client credentials from QA environment
# and copy them to test environment for isolated testing of the rotation of the JWT token
data "aws_iam_policy_document" "integration_test_policy" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
      "secretsmanager:RotateSecret",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.machine_name}/M2M_JWT_ACCESS_TOKEN",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.machine_name}/M2M_JWT_ACCESS_TOKEN*",
    ]
  }
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:qa/${var.machine_name}/M2M_AUTH0_CLIENT_CREDENTIALS",
      "arn:aws:secretsmanager:*:*:secret:qa/${var.machine_name}/M2M_AUTH0_CLIENT_CREDENTIALS*",
    ]
  }
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:PutSecretValue",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.machine_name}/M2M_AUTH0_CLIENT_CREDENTIALS",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.machine_name}/M2M_AUTH0_CLIENT_CREDENTIALS*",
    ]
  }
}

resource "aws_iam_policy" "integration_test_policy" {
  name   = "${var.environment}-${var.lambda_name}-integration-test"
  policy = data.aws_iam_policy_document.integration_test_policy.json
}

# Jenkins requires ability to AssumeRole for running integration tests
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "jenkins_assume_role" {
  name               = "${var.environment}-${var.lambda_name}-integration-test"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Allow the role that Jenkins assumes to perform SecretsManager operations related to Integration Test
resource "aws_iam_role_policy_attachment" "integration_test_assume_role_policy_attachment" {
  role       = aws_iam_role.jenkins_assume_role.id
  policy_arn = aws_iam_policy.integration_test_policy.arn
}


#### CREATE AWS SECRETS MANAGER SECRET PAIR
module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.machine_name
  application_family = var.application_family
}