provider "aws" {
  region = var.region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-permissions-platform-terraform-state"
    key     = "qa/lambda-auth0-m2m-token-secret-rotation/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.0.0"

  environment = var.environment
}

module "lambda" {
  source                  = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"
  lambda_name             = var.lambda_name
  lambda_description      = "Lambda to rotate Auth0 M2M token secret"
  lambda_function_timeout = 900 # 15 minutes
  environment             = var.environment
  application_family      = var.application_family

  lambda_function_memory_size                    = 512
  lambda_function_reserved_concurrent_executions = var.lambda_function_reserved_concurrent_executions

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids

  use_container_image = true

  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT        = var.environment
    AUTH0_URL          = var.auth0_url
    SENTRY_ENVIRONMENT = data.aws_caller_identity.current.account_id
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.secrets_manager_policy.arn,
  ]

  additional_tags = var.additional_tags

  # This is precisely the thing we are trying to eliminate
  # Let's not depend on it being here.
  ows_machine_to_machine_enabled = false
}

# Policy to get access to secrets and write to token secret
data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
    ]

    resources = [
      "arn:aws:secretsmanager:${var.region}:*:secret:${var.environment}/*/M2M_AUTH0_CLIENT_CREDENTIALS",
      "arn:aws:secretsmanager:${var.region}:*:secret:${var.environment}/*/M2M_AUTH0_CLIENT_CREDENTIALS*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/*/M2M_JWT_ACCESS_TOKEN",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/*/M2M_JWT_ACCESS_TOKEN*",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:PutSecretValue",
      "secretsmanager:UpdateSecretVersionStage",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/*/M2M_JWT_ACCESS_TOKEN",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/*/M2M_JWT_ACCESS_TOKEN*",
    ]
  }
}

resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.lambda_name}-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# Only create this once in the PP QA account
module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry//?ref=4.0.2"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

# Only create this once in the PP QA account
module "datadog" {
  source       = "git@github.com:theorchard/terraform-datadog//modules/lambda?ref=6.6.0"
  environment  = var.environment
  service_name = var.lambda_name
  teams        = ["permissions-platform"]

  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

resource "datadog_monitor" "lambda_throttle_monitor" {
  name               = "${var.environment}-${var.lambda_name}-throttle-monitor"
  type               = "query alert"
  message            = "Monitor triggered. Notify: ${var.notification_endpoints}"
  escalation_message = "Escalation to ${var.notification_endpoints}"

  query = "sum(${var.lambda_throttle_time}):sum:aws.lambda.throttles{environment:${var.environment},service_name:${var.lambda_name}} by {aws_account}.as_count() > ${var.lambda_throttle_critical_number}"

  monitor_thresholds {
    ok                = var.lambda_throttle_ok_number
    critical          = var.lambda_throttle_critical_number
    warning           = var.lambda_throttle_warning_number
    warning_recovery  = var.lambda_throttle_warning_recovery_number
    critical_recovery = var.lambda_throttle_critical_recovery_number
  }

  include_tags        = true
  notify_no_data      = false
  notify_audit        = false
  renotify_interval   = 60
  timeout_h           = 0
  require_full_window = false

  tags = local.datadog_tags
}

resource "aws_lambda_permission" "allow_secrets_manager_invocation" {
  statement_id  = "SecretsManager-${module.lambda.lambda_name}-M2M_JWT_ACCESS_TOKEN"
  action        = "lambda:InvokeFunction"
  function_name = module.lambda.lambda_name
  principal     = "secretsmanager.amazonaws.com"
  source_arn    = "arn:aws:secretsmanager:${var.region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/*/M2M_JWT_ACCESS_TOKEN*"
}