provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-permissions-platform-terraform-state"
    key     = "qa/pdp-backfill/bucket/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.7"

  env                = var.environment
  bucket_name        = var.bucket_name
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
  s3_read_only_policy                 = true
  enable_guardduty_malware_protection = true
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/s3?ref=6.16.2"

  environment                       = var.environment
  service_name                      = var.bucket_name
  application_family                = var.application_family
  teams                             = ["permissions-platform"]
  notification_endpoints            = "@slack-permissions-platform-alerts"
  escalation_notification_endpoints = "@slack-permissions-platform-alerts"

  dashboard_configuration = {
    enabled                       = false
    show_advanced_storage_metrics = false
    show_replication_metrics      = false
    show_standard_storage_metrics = false
  }

  guardduty_malware_monitor_configuration = {
    enabled = true
  }
}

resource "aws_s3_bucket_notification" "bucket_notification" {
  bucket      = module.s3_bucket.s3_bucket_name_output
  eventbridge = true
}

# Jenkins pipeline agents assume this role in order to run deploys.
data "aws_iam_role" "jenkins_deploy_role" {
  name = "${var.environment}-jenkins-pipeline-deploy-role"
}

data "aws_iam_policy_document" "jenkins_deploy_role_policy_document" {
  statement {
    sid    = "AllowPdpQaRefreshFileUploads"
    effect = "Allow"
    actions = [
      "s3:PutObject",
    ]
    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/pdp_qa_refresh/*"
    ]
  }
}

resource "aws_iam_policy" "jenkins_deploy_role_policy" {
  name        = "Jenkins-pipeline-deploy-pdp-qa-refresh-policy"
  description = "Jenkins pipeline deploy PDP QA Refresh Files policy"
  policy      = data.aws_iam_policy_document.jenkins_deploy_role_policy_document.json
}

# Attach iam policies to Jenkins deploy role.
resource "aws_iam_role_policy_attachment" "jenkins_deploy_role_policy_attachment" {
  role       = data.aws_iam_role.jenkins_deploy_role.id
  policy_arn = aws_iam_policy.jenkins_deploy_role_policy.arn
}