provider "aws" {
  region = var.aws_region
}


# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-permissions-platform-terraform-state"
    key     = "qa/pdp-backfill/integration-test/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}


data "aws_secretsmanager_secret" "qa_pdp_backfill_m2m_token_secret" {
  name = "qa/pdp-backfill/M2M_JWT_ACCESS_TOKEN"
}

data "aws_iam_policy_document" "integration_test_policy" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [
      data.aws_secretsmanager_secret.qa_pdp_backfill_m2m_token_secret.arn
    ]
  }
}

resource "aws_iam_policy" "integration_test_policy" {
  name   = "SecretsManager${var.environment}-${var.service_name}-policy"
  policy = data.aws_iam_policy_document.integration_test_policy.json
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "jenkins_assume_role" {
  name               = "${var.environment}-${var.service_name}-integration-test"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "integration_test_secrets_attachment" {
  role       = aws_iam_role.jenkins_assume_role.id
  policy_arn = aws_iam_policy.integration_test_policy.arn
}

data "aws_iam_policy" "s3_ro_policy" {
  name = "S3-${var.environment}-${var.service_name}-read-only"
}

resource "aws_iam_role_policy_attachment" "integration_test_s3_attachment" {
  role       = aws_iam_role.jenkins_assume_role.id
  policy_arn = data.aws_iam_policy.s3_ro_policy.arn
}