module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}


# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-permissions-platform-terraform-state"
    key     = "qa/pdp-backfill/refresh-sfn/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_sfn_state_machine" "refresh_sfn" {
  name = "${var.environment}-dynamodb-refresh-sfn"
}

data "aws_iam_policy_document" "scheduler_can_start_refresh_sfn" {
  statement {
    effect = "Allow"

    actions = [
      "states:StartExecution",
    ]

    resources = [
      data.aws_sfn_state_machine.refresh_sfn.arn,
    ]
  }
}

resource "aws_iam_policy" "refresh_sfn_policy" {
  name   = "SFN-${var.environment}-execute-dynamodb-refresh-sfn-policy"
  policy = data.aws_iam_policy_document.scheduler_can_start_refresh_sfn.json
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

resource "aws_iam_role" "jenkins_assume_role" {
  name               = "${var.environment}-${var.service_name}-dynamodb-refresh-sfn-run-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "jenkins_attachment" {
  role       = aws_iam_role.jenkins_assume_role.id
  policy_arn = aws_iam_policy.refresh_sfn_policy.arn
}