locals {
  snowflake_integration_role_name = "${var.environment}-${var.team_name}-snowflake-integration-role"
}

data "aws_s3_bucket" "bucket" {
  bucket = "prod-abacus-adjustments"
}

resource "snowflake_storage_integration" "adjustments_s3_integration" {
  name             = "${var.environment}-${var.team_name}-s3-integration"
  storage_provider = "S3"

  storage_allowed_locations = ["s3://${data.aws_s3_bucket.bucket.bucket}/"]

  storage_aws_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${local.snowflake_integration_role_name}"
}

resource "snowflake_stage" "adjustments_s3_stage" {
  name                = "${var.environment}-${var.team_name}-adjustments-s3-stage"
  url                 = "s3://${data.aws_s3_bucket.bucket.bucket}/"
  database            = "ROYALTY_ACCOUNTING"
  schema              = "PROD"
  storage_integration = snowflake_storage_integration.adjustments_s3_integration.name
}

module "adjustments_stage_access" {
  source = "git@github.com:theorchard/terraform-snowflake.git//modules/roles/stage_access?ref=7.7.4"

  database = snowflake_stage.adjustments_s3_stage.database
  schema   = snowflake_stage.adjustments_s3_stage.schema
  stage    = snowflake_stage.adjustments_s3_stage.name
}

data "aws_iam_policy_document" "adjustments_s3_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"

    principals {
      type = "AWS"
      identifiers = [
        snowflake_storage_integration.adjustments_s3_integration.storage_aws_iam_user_arn,
        "arn:aws:iam::212740118925:user/91n1-s-vast5230"
      ]
    }

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values = [
        snowflake_storage_integration.adjustments_s3_integration.storage_aws_external_id,
        "DELPHI_SFCRole=2_8euM1CsNmtttxIRmMT40aGA5irk="
      ]
    }
  }
}

data "aws_iam_policy_document" "adjustments_s3_inline_policy" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:GetObjectVersion",
    ]
    resources = ["${data.aws_s3_bucket.bucket.arn}/*"]
  }

  statement {
    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation"
    ]
    resources = ["${data.aws_s3_bucket.bucket.arn}"]
  }
}

resource "aws_iam_role" "adjustments_s3_integration_role" {
  name               = local.snowflake_integration_role_name
  assume_role_policy = data.aws_iam_policy_document.adjustments_s3_assume_role_policy.json
}

resource "aws_iam_role_policy" "adjustments_s3_integration_policy" {
  name   = "${var.environment}-${var.team_name}-adjustments-bucket-snowflake-policy"
  role   = aws_iam_role.adjustments_s3_integration_role.id
  policy = data.aws_iam_policy_document.adjustments_s3_inline_policy.json
}