terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/altafonte-user-creation/songwhip/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "default_tags" {
  source = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

# Secrets for accessing Neo4j
module "songwhip_lambda_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 30
}

# SecretsManager access policy document
data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
    ]
  }
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# SecretsManager access policy
resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretManager-${var.environment}-${var.service_name}-access-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# Jenkins agents will assume this role in order to access SecretManager
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-lambda-songwhip-profile-creator-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SecretManager access policy to Jenkins role
resource "aws_iam_role_policy_attachment" "lambda_songwhip_profile_creator_secret_manager_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}

data "aws_iam_policy_document" "s3_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:PutObject"
    ]

    resources = [
      "arn:aws:s3:::${var.environment}-altafonte-user-ingestion/*",
    ]
  }
}

# S3 access policy
resource "aws_iam_policy" "s3_policy" {
  name   = "S3-${var.environment}-${var.service_name}-read-write-policy"
  policy = data.aws_iam_policy_document.s3_policy_document.json
}

module "lambda_songwhip_profile_creator" {
  source                   = "git@github.com:theorchard/terraform-lambda.git?ref=4.1.0"
  environment              = var.environment
  lambda_name              = var.service_name
  lambda_description       = "Creates songwhip profiles for existing users."
  lambda_function_timeout  = var.lambda_default_timeout
  use_container_image      = true
  vpc_subnet_ids           = module.vpc_info.default_private_subnet_ids
  vpc_enabled              = true
  vpc_id                   = module.vpc_info.vpc_id
  datadog_advanced_enabled = true
  application_family       = var.application_family

  lambda_function_environment_variables = {
    ENVIRONMENT          = var.environment
    NEO4J_URL            = var.neo4j_url
    NEO4J_MAX_RETRY_TIME = var.neo4j_max_retry_time
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.secrets_manager_policy.arn,
    aws_iam_policy.s3_policy.arn
  ]
}