data "aws_s3_bucket" "s3_orcd_raw_assets" {
  bucket = "${var.environment}-${var.orcd_raw_assets_bucket_name}"
}

data "aws_iam_policy_document" "artwork_backfill_s3_secret_policy" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject",
      "s3:GetObjectAttributes",
    ]

    resources = [
      "${data.aws_s3_bucket.s3_orcd_raw_assets.arn}/*",
    ]
  }
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket"
    ]

    resources = [
      data.aws_s3_bucket.s3_orcd_raw_assets.arn,
    ]
  }
  statement {
    effect = "Allow"

    resources = [
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.id}:secret:${var.environment}/${var.secret_service_name}/jwt_token*",
    ]

    actions = [
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:GetSecretValue",
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:DescribeSecret"
    ]
  }
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

# artwork s3 and secret policy.
resource "aws_iam_policy" "artwork_backfill_policy" {
  name   = "${var.environment}-artwork-backfill-policy"
  policy = data.aws_iam_policy_document.artwork_backfill_s3_secret_policy.json
}

# Jenkins agents will assume this role in order to access s3 and secrets
resource "aws_iam_role" "jenkins_artwork_backfill_role" {
  name                 = "${var.environment}-artwork-backfill-jenkins-role"
  assume_role_policy   = data.aws_iam_policy_document.assume_role_policy.json
  max_session_duration = 43200
}

# Attach s3 and secret policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "artwork_backfill_policy_attachment" {
  role       = aws_iam_role.jenkins_artwork_backfill_role.id
  policy_arn = aws_iam_policy.artwork_backfill_policy.arn
}