provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/awal-discovery-main/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "awal_discovery_main_fargate_environment" {
  
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws
  }

  environment                    = var.environment
  service_name                   = var.service_name
  aws_region                     = var.aws_region
  commit_sha                     = "latest"
  container_port                 = 9000
  task_type                      = "worker"
  desired_task_count             = 0
  task_cpu                       = 1024
  task_memory                    = 4096
  maximum_capacity               = 1
  minimum_capacity               = 0
  vpc_id                         = module.vpc_info.vpc_id
  fargate_service_subnets        = module.vpc_info.default_private_subnet_ids
  application_family             = var.application_family
  cloudwatch_event_enabled       = true
  cloudwatch_event_schedule      = "cron(1 11 ? * * *)"
  health_check_command           = "python --version"

  iam_managed_policy_attachments = [
    aws_iam_policy.awal_discovery_main_secrets_manager_policy.arn
  ]

  environment_variables = [
    {
      Environment = var.environment
    }
  ]
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

# Create secrets manager policy 
resource "aws_iam_policy" "awal_discovery_main_secrets_manager_policy" {
  name   = "Secretsmanager-${var.environment}-${var.service_name}-secrets-manager-policy"
  policy = data.aws_iam_policy_document.awal_discovery_main_secrets_manager_policy.json

  tags = {
    terraformed        = true
    application_family = var.application_family
  }
}

data "aws_iam_policy_document" "awal_discovery_main_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetSecretValue"
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/awal-ar/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/awal-ar/*"
    ]
  }

}