provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/aws-logs-437795906767-us-east-1/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

data "aws_iam_policy_document" "bucket_policy" {
  statement {
    sid = "AWSConsoleStmt-1505312177104"
    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::127311923021:root"]
    }

    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${module.log_bucket.s3_bucket_arn_output}/prod-ows-grass/AWSLogs/${data.aws_caller_identity.current.account_id}/*"
    ]
  }
}

module "log_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=2.7.1"
  env                 = var.environment
  bucket_name         = "aws-logs-${data.aws_caller_identity.current.account_id}-${var.aws_region}"
  custom_bucket_name  = "aws-logs-${data.aws_caller_identity.current.account_id}-${var.aws_region}"
  application_family  = var.application_family
  kms_key_enabled     = false
  s3_read_only_policy = false

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_policy_overrides = [
    data.aws_iam_policy_document.bucket_policy.json,
  ]
}

resource "aws_lambda_permission" "allow_bucket_execution" {
  statement_id  = "AllowExecutionFromS3Bucket"
  action        = "lambda:InvokeFunction"
  function_name = data.aws_lambda_function.datadog_lambda_function.arn
  principal     = "s3.amazonaws.com"
  source_arn    = module.log_bucket.s3_bucket_arn_output
}

resource "aws_s3_bucket_notification" "log_bucket_notification" {
  bucket = module.log_bucket.s3_bucket_name_output

  lambda_function {
    lambda_function_arn = data.aws_lambda_function.datadog_lambda_function.arn
    events              = ["s3:ObjectCreated:*"]
    filter_prefix       = "elasticmapreduce/"
  }
}