provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/aws-user-audit/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# IAM role.
resource "aws_iam_role" "access_role" {
  name               = "${var.environment}-${var.service_name}-access-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
  tags               = local.tags
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    principals {
      type        = "AWS"
      identifiers = var.trusted_principals
    }
  }
}

# Role permissions.
resource "aws_iam_policy" "iam_access_policy" {
  name   = "IAM-${var.environment}-${var.service_name}-access-policy"
  policy = data.aws_iam_policy_document.iam_access_policy.json
}

data "aws_iam_policy_document" "iam_access_policy" {
  statement {
    effect = "Allow"
    actions = [
      "iam:GetAccessKeyLastUsed",
      "iam:ListAccessKeys",
      "iam:ListAttachedUserPolicies",
      "iam:ListGroups",
      "iam:ListGroupsForUser",
      "iam:ListUserPolicies",
      "iam:ListUsers",
      "iam:ListUserTags",
      "iam:GetLoginProfile",
    ]
    resources = ["*"]
  }
}

resource "aws_iam_role_policy_attachment" "iam_access_policy_attachment" {
  role       = aws_iam_role.access_role.id
  policy_arn = aws_iam_policy.iam_access_policy.arn
}

resource "aws_iam_policy" "s3_access_policy" {
  name   = "S3-${var.environment}-${var.service_name}-access-policy"
  policy = data.aws_iam_policy_document.s3_access_policy.json
}

data "aws_iam_policy_document" "s3_access_policy" {
  statement {
    effect    = "Allow"
    actions   = ["s3:PutObject"]
    resources = ["arn:aws:s3:::prod-orcdbucket/aws-iam-user-audit/*"]
  }
}

resource "aws_iam_role_policy_attachment" "s3_access_policy_attachment" {
  role       = aws_iam_role.access_role.id
  policy_arn = aws_iam_policy.s3_access_policy.arn
}

resource "aws_iam_policy" "ses_access_policy" {
  name   = "SES-${var.environment}-${var.service_name}-access-policy"
  policy = data.aws_iam_policy_document.ses_access_policy.json
}

data "aws_iam_policy_document" "ses_access_policy" {
  statement {
    effect    = "Allow"
    actions   = ["ses:SendEmail", "ses:SendRawEmail"]
    resources = ["arn:aws:ses:us-east-1:437795906767:identity/donotreply@theorchard.com"]
  }
}

resource "aws_iam_role_policy_attachment" "ses_access_policy_attachment" {
  role       = aws_iam_role.access_role.id
  policy_arn = aws_iam_policy.ses_access_policy.arn
}