module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  additional_tags    = {
    terraformed = "true"
  }
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/base-amis/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_role" "autoscaling_role" {
  name = "AWSServiceRoleForAutoScaling"
}

# Data resource for access to the shared AMI KMS key
data "aws_iam_policy_document" "ami_kms_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "kms:CreateGrant",
    ]
    resources = [
      var.shared_ami_kms_key_arn,
    ]
  }
}

# Creates policy for read-only access to the S3 bucket. Intended to be used by ECS task roles in entrypoint scripts.
resource "aws_iam_policy" "ami_kms_policy" {
  name   = "KMS-shared-${var.service_name}-RO"
  policy = data.aws_iam_policy_document.ami_kms_policy_document.json
}

resource "aws_kms_grant" "autoscaling_kms_grant" {
  name              = "autoscaling-kms-grant"
  key_id            = var.shared_ami_kms_key_arn
  grantee_principal = data.aws_iam_role.autoscaling_role.arn
  operations        = ["Encrypt", "Decrypt", "ReEncryptFrom", "ReEncryptTo", "GenerateDataKey", "GenerateDataKeyWithoutPlaintext", "DescribeKey", "CreateGrant",]
}