data "aws_iam_policy_document" "handle_artwork_lambda_policy_document" {
  statement {
    effect    = "Allow"
    resources = [
      "${data.aws_s3_bucket.raw_asset_bucket.arn}/*"
    ]

    actions   = [
      "s3:PutObject"
    ]
  }
}

resource "aws_iam_policy" "handle_artwork_lambda_policy" {
  name        = "${var.environment}-bulk-assets-ingester-handle-artwork-lambda-policy"
  description = "handle_artwork bulk-assets-ingester lambda policy"
  policy      = data.aws_iam_policy_document.handle_artwork_lambda_policy_document.json
}

module "lambda_handle_artwork" {
  source = "git@github.com:theorchard/terraform-lambda.git?ref=3.1.9"

  environment                 = var.environment
  lambda_name                 = "lambda-${var.service_name}-handle-artwork"
  application_family          = "integrations"
  lambda_description          = "Send product artwork assets to ows-assets via GraphQL queries"
  lambda_function_memory_size = 1024
  use_container_image         = true

  lambda_function_environment_variables = {
    Environment                 = var.environment
    LOGGER_DSN                  = var.logger_dsn
    SENTRY_DSN                  = module.sentry_handle_artwork_lambda.sentry_key_dsn_public_output
    OA_USER                     = var.oa_user
    GRAPHQL_GATEWAY_URL         = var.graphql_gateway_url
    SNOWFLAKE_S3_BUCKET         = var.snowflake_s3_bucket
    SNOWFLAKE_S3_LOCATION       = var.snowflake_s3_location
    CATALOG_INGESTION_SOURCE_ID = var.catalog_ingestion_id
  }

  vpc_enabled                                    = true
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_timeout                        = var.lambda_default_timeout
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments                 = [
    aws_iam_policy.common_lambda_policy.arn,
    aws_iam_policy.handle_artwork_lambda_policy.arn
  ]
}