data "aws_iam_policy_document" "trigger_state_machine_lambda_policy_document" {
  statement {
    actions = [
      "states:StartExecution",
    ]

    resources = [
      aws_sfn_state_machine.sfn_bulk_assets_ingester.arn,
    ]
  }
}

resource "aws_iam_policy" "trigger_state_machine_lambda_policy" {
  name        = "${var.environment}-bulk-assets-ingester-trigger-state-machine-lambda-policy"
  description = "trigger_state_machine bulk-assets-ingester lambda policy"
  policy      = data.aws_iam_policy_document.trigger_state_machine_lambda_policy_document.json
}

# Lambda definition for 'trigger-state-machine' lambda
module "lambda_trigger_state_machine" {
  source = "git@github.com:theorchard/terraform-lambda.git?ref=3.1.9"

  environment              = var.environment
  lambda_name              = "lambda-${var.service_name}-trigger-sfn"
  application_family       = "integrations"
  lambda_description       = "Handles triggering the Bulk Asssets Ingester state machine with an appropriate name"
  use_container_image      = true

  lambda_function_environment_variables = {
    Environment                   = var.environment
    LOGGER_DSN                    = var.logger_dsn
    SENTRY_DSN                    = module.sentry_trigger_state_machine_lambda.sentry_key_dsn_public_output
    BULK_ASSETS_STATE_MACHINE_ARN = aws_sfn_state_machine.sfn_bulk_assets_ingester.arn
  }

  vpc_enabled                                    = true
  vpc_id                                         = var.vpc_id
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_timeout                        = var.lambda_default_timeout
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions_low
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments                 = [
    aws_iam_policy.trigger_state_machine_lambda_policy.arn
  ]
}