module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/bulk-upload-feeder/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_s3_bucket" "bulk_operations_bucket" {
  bucket = "${var.environment}-bulk-operations"
}

module "s3_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.2.0"

  buckets = [{
    bucket = data.aws_s3_bucket.bulk_operations_bucket.bucket
  }]
  action_types = ["read", "write", "delete"]
}

resource "aws_iam_policy" "s3_policy" {
  name   = "S3-${var.environment}-${var.service_name}-read-write-policy"
  policy = module.s3_policy.policy.json
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

resource "aws_iam_role" "bulk_upload_feeder_role" {
  name = "${var.environment}-${var.service_name}-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_user" "bulk_upload_feeder_user" {
  name = var.service_name

  tags = {
    terraformed = true
    role        = "service-user"
  }
}

resource "aws_iam_role_policy_attachment" "bulk_upload_feeder_role_policy_attachment" {
  role       = aws_iam_role.bulk_upload_feeder_role.name
  policy_arn = aws_iam_policy.s3_policy.arn
}

resource "aws_iam_user_policy_attachment" "bulk_upload_feeder_user_policy_attachment" {
  policy_arn = aws_iam_policy.s3_policy.arn
  user       = aws_iam_user.bulk_upload_feeder_user.name
}