provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/checkov/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# IAM role.
resource "aws_iam_role" "access_role" {
  name               = "${var.environment}-${var.service_name}-access-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
  tags               = local.tags
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    principals {
      type        = "AWS"
      identifiers = var.trusted_principals
    }
  }
}

# Role permissions.
resource "aws_iam_policy" "access_policy" {
  name   = "${var.environment}-${var.service_name}-access-policy"
  policy = data.aws_iam_policy_document.access_policy.json
}

data "aws_iam_policy_document" "access_policy" {
  statement {
    effect = "Allow"
    actions = [
      "ec2:DescribeSubnets",
      "ec2:DescribeSecurityGroups",
    ]
    resources = ["*"]
  }
}

resource "aws_iam_role_policy_attachment" "access_policy_attachment" {
  role       = aws_iam_role.access_role.id
  policy_arn = aws_iam_policy.access_policy.arn
}