module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/content-review/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.4"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "content_review_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=6.6.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]
  rds_engine_version                        = "8.0.mysql_aurora.3.10.3"
  rds_cluster_instance_class                = "db.r6g.large"
  rds_cluster_instance_count                = "1"
  rds_db_subnet_group_name                  = "${var.environment}-orchard-private-subnet-group"
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
  rds_db_cluster_parameter_group_name       = "aurora-mysql80sync"
  rds_performance_insights_enabled          = true
  rds_master_username                       = "dummy"
  rds_master_password                       = "dummy"
  additional_tags                           = var.additional_tags
  custom_kms_key_enabled                    = false
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.zone_id
}

module "content_review_rds_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/rds?ref=6.13.4"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  notification_endpoints            = var.monitor_notification_endpoint
  escalation_notification_endpoints = var.monitor_escalation_notification_endpoint
}

module "content_review_match_audio_match_dynamodb_table" {
  source             = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"
  env                = var.environment
  table_name         = "${replace(var.service_name, "-", "_")}_match_audio_match"
  hash_key           = "asset_final_id"
  application_family = var.application_family
  use_on_demand      = true

  attribute = [
    {
      name = "asset_final_id"
      type = "N"
    }
  ]
}