module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_caller_identity" "current" {
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/cypress-worker/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_iam_policy_document" "cypress_worker_task_policy" {
  statement {
    actions = [
      "ec2:DescribeSecurityGroups",
      "ecs:DescribeClusters",
      "ecs:DescribeTasks",
      "ecs:DescribeTaskDefinition",
      "ecs:ListTasks",
      "ecs:ListTaskDefinitions",
    ]
    effect = "Allow"

    resources = [
      "*",
    ]
  }

  statement {
    actions = [
      "ecs:RunTask",
      "ecs:StartTask",
    ]

    resources = [
      "arn:aws:ecs:*:${data.aws_caller_identity.current.account_id}:cluster/${var.environment}-${var.service_name}",
      "arn:aws:ecs:*:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}:*"
    ]
  }

  statement {
    actions = [
      "iam:PassRole",
    ]
    effect = "Allow"
    resources = [
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-${var.service_name}-role",
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-${var.service_name}-task-execution-role*",
      "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/${var.environment}-${var.service_name}-task-role"
    ]
  }
}

data "aws_iam_policy_document" "cypress_worker_assume_role_policy_document" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "cypress_worker_role" {
  name               = "${var.environment}-cypress-worker-role"
  assume_role_policy = data.aws_iam_policy_document.cypress_worker_assume_role_policy_document.json
  tags = {
    environment        = var.environment
    terraformed        = "true"
    application_family = var.application_family
  }
}

resource "aws_iam_policy" "cypress_worker_fargate_tasks_policy" {
  name   = "Task-${var.environment}-${var.service_name}-run-task-policy"
  policy = data.aws_iam_policy_document.cypress_worker_task_policy.json

  tags = {
    environment        = var.environment
    terraformed        = "true"
    application_family = var.application_family
  }
}
resource "aws_iam_role_policy_attachment" "cypress_worker_fargate_tasks_policy_attachment" {
  role       = aws_iam_role.cypress_worker_role.name
  policy_arn = aws_iam_policy.cypress_worker_fargate_tasks_policy.arn
}

# Re-using the qa secrets manager policy as both environments need the same secrets access
data "aws_iam_policy" "cypress_worker_secrets_manager_policy" {
  name = "Secretsmanager-qa-${var.service_name}-secrets-manager-policy"

}
# Re-using the qa secrets manager policy as both environments need the same s3 access
data "aws_iam_policy" "s3_cypress_worker_read_write_policy" {
  name = "S3-qa-${var.service_name}-read-write-policy"
}
# Re-using the qa dynamoDb policy as both environments need the same access
data "aws_iam_policy" "cypress_dynamoDb_policy" {
  name = "DynamoDb-qa-${var.service_name}-read-write-policy"
}

# Re-using qa lambda policy as both environments nee the same lambda access
data "aws_iam_policy" "cypress_lambda_access_policy" {
  name = "qa-${var.service_name}-lambda-access-policy"
}

module "cypress_worker_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws.networking
  }

  environment          = var.environment
  service_name         = var.service_name
  aws_region           = var.aws_region
  application_family   = var.application_family
  commit_sha           = "latest"
  task_type            = "worker"
  container_port       = 9000
  desired_task_count   = 0
  minimum_capacity     = 0
  maximum_capacity     = 200
  task_cpu             = 4096
  task_memory          = 12288
  vpc_id               = module.vpc_info.vpc_id
  health_check_command = "$(npm bin)/cypress verify"


  iam_managed_policy_attachments = [
    data.aws_iam_policy.cypress_worker_secrets_manager_policy.arn,
    data.aws_iam_policy.s3_cypress_worker_read_write_policy.arn,
    aws_iam_policy.cypress_worker_fargate_tasks_policy.arn,
    data.aws_iam_policy.cypress_dynamoDb_policy.arn,
    data.aws_iam_policy.cypress_lambda_access_policy.arn
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
  ]
}

module "cypress_worker_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.16.1"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  notification_endpoints            = "@slack-cucumber-cypress-development"
  escalation_notification_endpoints = "@slack-cucumber-cypress-development"
  application_family                = var.application_family
}