data "aws_iam_policy_document" "video_mediaconvert_assume_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type        = "Service"
      identifiers = ["mediaconvert.amazonaws.com"]
    }
  }
}

resource "aws_iam_role" "video_mediaconvert_role" {
  name               = "${var.environment}-video-mediaconvert-role"
  assume_role_policy = data.aws_iam_policy_document.video_mediaconvert_assume_role_policy_document.json
}

resource "aws_iam_role_policy_attachment" "video_mediaconvert_role_blank_dir_readonly_policy_attachment" {
  role       = aws_iam_role.video_mediaconvert_role.id
  policy_arn = aws_iam_policy.s3_blank_dir_readonly_policy.arn
}

resource "aws_iam_role_policy_attachment" "video_mediaconvert_role_s3_raw_dir_readonly_policy_attachment" {
  role       = aws_iam_role.video_mediaconvert_role.id
  policy_arn = data.aws_iam_policy.s3_raw_dir_readonly_policy.arn
}

resource "aws_iam_role_policy_attachment" "video_mediaconvert_role_s3_streamable_preview_dir_putonly_policy_attachment" {
  role       = aws_iam_role.video_mediaconvert_role.id
  policy_arn = aws_iam_policy.s3_streamable_preview_dir_putonly_policy.arn
}

resource "aws_iam_role_policy_attachment" "video_mediaconvert_role_s3_thumbnails_dir_putonly_policy_attachment" {
  role       = aws_iam_role.video_mediaconvert_role.id
  policy_arn = aws_iam_policy.s3_thumbnails_dir_putonly_policy.arn
}

resource "aws_iam_role_policy_attachment" "video_mediaconvert_role_s3_mezzanine_dir_putonly_policy_attachment" {
  role       = aws_iam_role.video_mediaconvert_role.id
  policy_arn = aws_iam_policy.s3_mezzanine_dir_putonly_policy.arn
}

data "aws_iam_policy_document" "video_mediaconvert_create_job_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "mediaconvert:CreateJob",
    ]

    resources = [
      "arn:aws:mediaconvert:${var.region}:${data.aws_caller_identity.current.account_id}:queues/Default",
    ]
  }
}

resource "aws_iam_policy" "video_mediaconvert_create_job_policy" {
  name   = "${var.environment}-video-mediaconvert-create-job"
  policy = data.aws_iam_policy_document.video_mediaconvert_create_job_policy_document.json
}

data "aws_iam_policy_document" "video_mediaconvert_get_job_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "mediaconvert:GetJob",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "video_mediaconvert_get_job_policy" {
  name   = "${var.environment}-video-mediaconvert-get-job"
  policy = data.aws_iam_policy_document.video_mediaconvert_get_job_policy_document.json
}

data "aws_iam_policy_document" "video_mediaconvert_get_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "iam:GetRole",
    ]

    resources = [
      aws_iam_role.video_mediaconvert_role.arn,
    ]
  }
}

resource "aws_iam_policy" "video_mediaconvert_get_role_policy" {
  name   = "${var.environment}-video-mediaconvert-get-role"
  policy = data.aws_iam_policy_document.video_mediaconvert_get_role_policy_document.json
}

data "aws_iam_policy_document" "video_mediaconvert_pass_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "iam:PassRole",
    ]

    resources = [
      aws_iam_role.video_mediaconvert_role.arn,
    ]
  }
}

resource "aws_iam_policy" "video_mediaconvert_pass_role_policy" {
  name   = "${var.environment}-video-mediaconvert-pass-role"
  policy = data.aws_iam_policy_document.video_mediaconvert_pass_role_policy_document.json
}