terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/datadog/on-call/abacus/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "datadog_team" "team" {
  filter_keyword = "abacus"
}

data "datadog_user" "on_call_team_users" {
  for_each                 = toset(var.on_call_users)
  filter                   = each.value
  exclude_service_accounts = true
}

data "datadog_user" "escalation_users" {
  for_each                 = toset(var.escalation_only_users)
  filter                   = each.value
  exclude_service_accounts = true
}

resource "datadog_on_call_schedule" "schedule" {
  name      = "Abacus On-Call Schedule"
  time_zone = "America/New_York"
  teams     = [data.datadog_team.team.id]

  layer {
    name           = "Layer 1"
    effective_date = "2025-11-25T15:42:50Z"
    rotation_start = "2025-11-19T05:00:00Z"

    interval {
      days    = 7
      seconds = 0
    }

    users = [for user in data.datadog_user.on_call_team_users : user.id]
  }
}

resource "datadog_on_call_escalation_policy" "escalation_policy" {
  name                       = "Abacus Escalation Policy"
  teams                      = [
    data.datadog_team.team.id,
  ]
  resolve_page_on_policy_end = false
  retries                    = 3

  step {
    assignment             = "default"
    escalate_after_seconds = 900

    target {
      schedule = datadog_on_call_schedule.schedule.id
    }
  }

  step {
    assignment             = "default"
    escalate_after_seconds = 900

    target {
      user = data.datadog_user.on_call_team_users["george.theka@sonymusic-pde.com"].id
    }
  }

  step {
    assignment             = "default"
    escalate_after_seconds = 1800

    target {
      user = data.datadog_user.escalation_users["tdenkinger@sonymusic-pde.com"].id
    }
  }
}

resource "datadog_on_call_team_routing_rules" "routing_rules" {
  id = data.datadog_team.team.id

  rule {
    escalation_policy = datadog_on_call_escalation_policy.escalation_policy.id
    urgency           = "dynamic"
  }
}