terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/datadog/on-call/accounts-permissions-platform-rotation/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# This is a schedule and escalation policy for the combined platform area on-call rotation,
# which includes multiple teams
data "datadog_team" "teams" {
  for_each       = toset(var.teams)
  filter_keyword = each.value
}

data "datadog_user" "on_call_team_users" {
  for_each                 = toset(var.on_call_users)
  filter                   = each.value
  exclude_service_accounts = true
}

data "datadog_user" "escalation_users" {
  for_each                 = toset(var.escalation_only_users)
  filter                   = each.value
  exclude_service_accounts = true
}

data "datadog_user" "support_rotation_users" {
  for_each                 = toset(var.support_rotation_users)
  filter                   = each.value
  exclude_service_accounts = true
}

resource "datadog_on_call_schedule" "schedule" {
  name      = "Accounts + Permissions Platform On-Call Schedule"
  time_zone = "America/New_York"
  teams     = [for team in data.datadog_team.teams : team.id]

  layer {
    name           = "Layer 1"
    effective_date = "2026-03-09T13:00:00Z"
    rotation_start = "2026-03-09T13:00:00Z"

    interval {
      days    = 7
      seconds = 0
    }

    users = [for user in var.on_call_users : data.datadog_user.on_call_team_users[user].id]
  }
}

resource "datadog_on_call_escalation_policy" "escalation_policy" {
  name                       = "Accounts + Permissions Platform Escalation Policy"
  teams                      = [for team in data.datadog_team.teams : team.id]
  resolve_page_on_policy_end = false
  retries                    = 3

  step {
    assignment             = "default"
    escalate_after_seconds = 1800

    target {
      schedule = datadog_on_call_schedule.schedule.id
    }
  }

  step {
    assignment             = "default"
    escalate_after_seconds = 1800

    target {
      user = data.datadog_user.escalation_users["amccown@sonymusic-pde.com"].id
    }
  }
}

resource "datadog_on_call_team_routing_rules" "routing_rules" {
  for_each = data.datadog_team.teams

  id = each.value.id

  rule {
    escalation_policy = datadog_on_call_escalation_policy.escalation_policy.id
    urgency           = "dynamic"
  }
}

# Working Hours Support Rotation
resource "datadog_on_call_schedule" "support_rotation" {
  name      = "Accounts + Permissions Platform (Working Hours) Support Rotation"
  teams     = [for team in data.datadog_team.teams : team.id]
  time_zone = "America/New_York"

  layer {
    name           = "Layer 1"
    users          = [for user in var.support_rotation_users : data.datadog_user.support_rotation_users[user].id]
    effective_date = "2026-03-10T08:00:00Z"
    rotation_start = "2026-03-10T08:00:00Z"
    interval {
      days    = 14
      seconds = 0
    }
  }
}