terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/datadog/on-call/content-creation/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "datadog_team" "team" {
  filter_keyword = "content-creation-management"
}

data "datadog_user" "layer_1_on_call_users" {
  for_each                 = toset(var.layer_1_on_call_users)
  filter                   = each.value
  exclude_service_accounts = true
}

data "datadog_user" "layer_2_on_call_users" {
  for_each                 = toset(var.layer_2_on_call_users)
  filter                   = each.value
  exclude_service_accounts = true
}

data "datadog_user" "escalation_users" {
  for_each                 = toset(var.escalation_only_users)
  filter                   = each.value
  exclude_service_accounts = true
}

resource "datadog_on_call_schedule" "schedule" {
  name      = "Content Creation On-Call Schedule"
  time_zone = "America/New_York"
  teams     = [data.datadog_team.team.id]

  layer {
    name           = "Layer 1"
    effective_date = "2025-07-21T15:50:45Z"
    rotation_start = "2025-07-21T05:00:00Z"

    interval {
      days    = 7
      seconds = 0
    }

    dynamic "restriction" {
      for_each = var.layer_1_restriction_days
      content {
        start_day  = restriction.value
        start_time = "01:00:00"
        end_day    = restriction.value
        end_time   = "09:00:00"
      }
    }

    users = [for user in data.datadog_user.layer_1_on_call_users : user.id]
  }

  layer {
    name           = "Layer 2"
    effective_date = "2025-07-21T15:50:45Z"
    rotation_start = "2025-07-21T13:00:00Z"

    interval {
      days    = 7
      seconds = 0
    }

    dynamic "restriction" {
      for_each = [
        { start_day = "monday", start_time = "09:00:00", end_day = "tuesday", end_time = "01:00:00" },
        { start_day = "tuesday", start_time = "09:00:00", end_day = "wednesday", end_time = "01:00:00" },
        { start_day = "wednesday", start_time = "09:00:00", end_day = "thursday", end_time = "01:00:00" },
        { start_day = "thursday", start_time = "09:00:00", end_day = "friday", end_time = "01:00:00" },
        { start_day = "friday", start_time = "09:00:00", end_day = "monday", end_time = "01:00:00" },
      ]
      content {
        start_day  = restriction.value.start_day
        start_time = restriction.value.start_time
        end_day    = restriction.value.end_day
        end_time   = restriction.value.end_time
      }
    }
    users = [for user in var.layer_2_on_call_users : data.datadog_user.layer_2_on_call_users[user].id]
  }
}

resource "datadog_on_call_escalation_policy" "escalation_policy" {
  name                       = "Content Creation Escalation Policy"
  teams                      = [
    data.datadog_team.team.id,
  ]
  resolve_page_on_policy_end = false
  retries                    = 0

  step {
    assignment             = "default"
    escalate_after_seconds = 1800

    target {
      schedule = datadog_on_call_schedule.schedule.id
    }
  }

  step {
    assignment             = "default"
    escalate_after_seconds = 1800

    target {
      user = data.datadog_user.escalation_users["tmartino@sonymusic-pde.com"].id
    }
  }

  step {
    assignment             = "default"
    escalate_after_seconds = 1800

    target {
      user = data.datadog_user.escalation_users["mthomas@sonymusic-pde.com"].id
    }
  }
}

resource "datadog_on_call_team_routing_rules" "routing_rules" {
  id = data.datadog_team.team.id

  rule {
    escalation_policy = datadog_on_call_escalation_policy.escalation_policy.id
    urgency           = "dynamic"
  }
}