data "fivetran_group" "prod_warehouse" {
  id = "gentry_invitro"
}

resource "fivetran_connector" "main" {
  group_id = data.fivetran_group.prod_warehouse.id
  service  = "aurora"

  destination_schema {
    prefix = "reportsdd"
  }

  config {
    host        = module.direct_delivery_rds_cluster.rds_cluster_endpoint
    port        = module.direct_delivery_rds_cluster.rds_cluster_port
    user        = "fivetran"
    tunnel_host = "fivetran.theorchard.io"
    tunnel_port = "2222"
    tunnel_user = "fivetran"
  }
}

resource "fivetran_connector_schedule" "main" {
  connector_id      = fivetran_connector.main.id
  sync_frequency    = 5
  pause_after_trial = false
}

resource "fivetran_connector_schema_config" "main" {
  connector_id           = fivetran_connector.main.id
  schema_change_handling = "ALLOW_COLUMNS"
  schemas = {
    direct_delivery = {
      enabled = true
      tables = { for table in var.tables_to_sync_to_snowflake : table => {
        enabled = true
      } }
    }
  }
}