provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}


# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/distribution/distro-scripts/conflict-manager-elasticsearch-sync/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.3.0"

  secrets      = formatlist("${var.environment}/${var.service_name}/%s", var.secrets_manager_secret_names)
  action_types = ["read"]

  depends_on = [
    module.multiple_secrets_with_same_settings,
  ]
}

resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-scheduler-jenkins-policy"
  policy = module.secrets_manager_policy.policy.json
}

data "aws_iam_policy" "open_search_rw_policy" {
  name = var.open_search_rw_policy
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

resource "aws_iam_role" "scheduler_jenkins_role" {
  name = "${var.environment}-${var.service_name}-scheduler-jenkins-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "scheduler_jenkins_role_policy_attachment" {
  role       = aws_iam_role.scheduler_jenkins_role.name
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}

resource "aws_iam_role_policy_attachment" "os_conflict_manager_attachment" {
  role       = aws_iam_role.scheduler_jenkins_role.name
  policy_arn = data.aws_iam_policy.open_search_rw_policy.arn
}