provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}


# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/distribution/distro-scripts/distro-bug-monitoring/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.Environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}


data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent"
      ]
    }
  }
}

# Secret Manager policy document.
data "aws_iam_policy_document" "distro_bug_monitoring_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetSecretValue"
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.Environment}/${var.service_name}/*",
      "arn:aws:secretsmanager:*:*:secret:${var.Environment}/${var.service_name}/",
    ]
  }
}

resource "aws_iam_role" "assume_jenkins_role" {
  name               = "${var.Environment}-${var.service_name}-jenkins-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_policy" "distro_bug_monitoring_secretmanager_policy" {
  name              = "secretmanager-${var.Environment}-${var.service_name}-policy"
  policy            = data.aws_iam_policy_document.distro_bug_monitoring_secrets_manager_policy.json
}

resource "aws_iam_role_policy_attachment" "distro_bug_monitoring_role_policy_attachment" {
  role       = aws_iam_role.assume_jenkins_role.name
  policy_arn = aws_iam_policy.distro_bug_monitoring_secretmanager_policy.arn
}