module "default_tags" {
  source = "git@github.com:theorchard/terraform-default-tags.git?ref=2.0.0"

  environment        = var.environment
  application_family = var.application_family
  service_name       = var.meta_script_name
  team_name          = var.team_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/datadog/distribution/distro-scripts/meta-takedown/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "jenkins_scheduler_assume_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

resource "aws_iam_role" "meta_takedown_jenkins_role" {
  name                  = "${var.environment}-meta-force-takedown-jenkins-role"
  force_detach_policies = true
  assume_role_policy    = data.aws_iam_policy_document.jenkins_scheduler_assume_role.json
}

# Read access to SFTP key and Meta AWS credentials in Secrets Manager
module "meta_takedown_secrets_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets = [
    "${var.environment}/${var.meta_script_name}/META_SFTP_AWS_CREDENTIALS",
    "${var.environment}/${var.meta_script_name}/META_SFTP_PKEY",
  ]
  action_types = ["read"]
}

resource "aws_iam_role_policy" "meta_takedown_secrets_policy" {
  name   = "${var.environment}-${var.meta_script_name}-secrets-policy"
  role   = aws_iam_role.meta_takedown_jenkins_role.id
  policy = module.meta_takedown_secrets_policy.policy.json
}

# Read/Write access to S3 buckets used for SRR delivery
module "meta_takedown_s3_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.4.0"

  buckets = [
    { bucket = "qa-sr-interm-delivery-bucket", prefixes = ["fingerprinting/"] },
  ]
  action_types = ["read", "write"]
}

resource "aws_iam_role_policy" "meta_takedown_s3_policy" {
  name   = "${var.environment}-${var.meta_script_name}-s3-policy"
  role   = aws_iam_role.meta_takedown_jenkins_role.id
  policy = module.meta_takedown_s3_policy.policy.json
}