provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}


# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/distribution/distro-scripts/update-subaccount-id-mapping/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# Secret Manager policy document.
data "aws_iam_policy_document" "update-subaccount-id-mapping-secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetSecretValue"
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.Environment}/${var.service_name}/*",
      "arn:aws:secretsmanager:*:*:secret:${var.Environment}/${var.service_name}/",
    ]
  }
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.0.3"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.Environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

# Jenkins agents will assume this role in order to read from secrets manager
resource "aws_iam_role" "read_from_secrets_manager_role" {
  name               = "${var.Environment}-${var.service_name}-read-secrets-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_policy" "update_subaccount_id_mapping_secretmanager_policy" {
  name              = "secretmanager-${var.Environment}-${var.service_name}-policy"
  policy            = data.aws_iam_policy_document.update-subaccount-id-mapping-secrets_manager_policy.json
}