module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/distribution/scripts-assets/invoke-hive-ai-detection/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_policy_document" "pipeline_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

# Secret Manager policy document.
data "aws_iam_policy_document" "invoke_hive_ai_detection_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetSecretValue"
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
    ]
  }
}

data "aws_iam_policy_document" "invoke_hive_ai_detection_lambda_invoke_policy" {
  statement {
    actions = [
      "lambda:InvokeFunction"
    ]

    resources = [
      "arn:aws:lambda:${var.region}:${data.aws_caller_identity.current.account_id}:function:${var.environment}-lambda-assets-hive-ai-detection"      
    ]
  }
}

resource "aws_iam_role" "assume_jenkins_role" {
  name               = "${var.environment}-${var.service_name}-jenkins-role"
  assume_role_policy = data.aws_iam_policy_document.pipeline_assume_role_policy.json
}

resource "aws_iam_policy" "invoke_hive_ai_detection_secretmanager_policy" {
  name   = "secretmanager-${var.environment}-${var.service_name}-policy"
  description = "Grants read access to Secrets Manager secrets for Hive AI detection Jenkins pipeline"
  policy = data.aws_iam_policy_document.invoke_hive_ai_detection_secrets_manager_policy.json
}

resource "aws_iam_policy" "invoke_hive_ai_detection_lambda_invoke_policy" {
  name   = "lambda-invoke-${var.environment}-${var.service_name}-policy"
  policy = data.aws_iam_policy_document.invoke_hive_ai_detection_lambda_invoke_policy.json
}

resource "aws_iam_role_policy_attachment" "invoke_hive_ai_detection_role_policy_attachment" {
  role       = aws_iam_role.assume_jenkins_role.name
  policy_arn = aws_iam_policy.invoke_hive_ai_detection_secretmanager_policy.arn
}

resource "aws_iam_role_policy_attachment" "invoke_hive_ai_detection_lambda_invoke_role_policy_attachment" {
  role       = aws_iam_role.assume_jenkins_role.name
  policy_arn = aws_iam_policy.invoke_hive_ai_detection_lambda_invoke_policy.arn
}