data "aws_iam_policy_document" "pipeline_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

data "aws_iam_policy_document" "spatial_asset_ingester_secrets_s3_policy" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}/*",
    ]

    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:ListBucket",
    ]
    resources = [
      "arn:aws:s3:::${var.environment}-dolby-atmos-packager-alpha-input/*",
      "arn:aws:s3:::${var.environment}-dolby-atmos-packager-alpha-input",
    ]
  }
}

resource "aws_iam_role" "spatial_asset_ingester_assume_role" {
  name                 = "${var.environment}-${var.service_name}-secrets-s3-assume-role"
  assume_role_policy   = data.aws_iam_policy_document.pipeline_assume_role_policy.json
  max_session_duration = 43200
}

resource "aws_iam_role_policy" "spatial_asset_ingester_policy" {
  name = "${var.environment}-${var.service_name}-inline-secrets-access"
  role = aws_iam_role.spatial_asset_ingester_assume_role.id

  policy = data.aws_iam_policy_document.spatial_asset_ingester_secrets_s3_policy.json
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
}