provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/documents/knr-payments/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}


module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.14.1"

  env                 = var.environment
  bucket_name         = var.s3_bucket_name
  acceleration_status = "Enabled"
  application_family  = var.application_family
  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # CORS Rules
  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["GET"]
      allowed_origins = ["*"]
      expose_headers  = []
      max_age_seconds = 3000
    }
  ]

  lifecycle_rules_options_noncurrent_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 35
      storage_class = "STANDARD_IA"
    }
  ]
}

data "aws_iam_policy_document" "s3_input_bucket_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:HeadBucket",
      "s3:ListBucket",
      "s3:GetObjectVersion",
      "s3:GetObject",
      "s3:PutObject",
      "s3:BypassGovernanceRetention",
      "s3:GetBucketObjectLockConfiguration",
      "s3:GetObjectLegalHold",
      "s3:GetObjectRetention",
      "s3:PutBucketObjectLockConfiguration",
      "s3:PutObjectLegalHold",
      "s3:PutObjectRetention",
      "s3:ListObjectVersions",
      "s3:ListBucketVersions",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}",
      "${module.s3_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "s3_input_bucket_policy" {
  name        = "S3-${module.s3_bucket.s3_bucket_name_output}-RW"
  description = "Read, Write access to lambda-documents knr-payments bucket"
  policy      = data.aws_iam_policy_document.s3_input_bucket_policy.json
}

#################################
#
# lambda configuration
#
##################################
module "lambda_documents_knr_payments" {
  # checkov:skip=CKV_AWS_116:Silencing Checkov false warning as the DLQ is actually enabled
  source                   = "git@github.com:theorchard/terraform-lambda.git?ref=4.3.0"
  environment              = var.environment
  lambda_name              = var.lambda_name
  lambda_description       = "Generates a payment file for KNR"
  datadog_enabled          = var.datadog_enabled
  datadog_advanced_enabled = var.datadog_advanced_enabled

  application_family = var.application_family

  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions
  lambda_function_timeout                           = "300"
  use_container_image                               = true

  vpc_id                  = var.vpc_id
  vpc_subnet_ids          = var.vpc_subnet_ids
  zappa_s3_policy_enabled = false


  lambda_function_environment_variables = {
    Environment = var.environment
    SNOWFLAKE_ACCOUNT   = var.lambda_snowflake_account
    SNOWFLAKE_DATABASE  = var.lambda_snowflake_database
    SNOWFLAKE_SCHEMA    = var.lambda_snowflake_schema
    SNOWFLAKE_WAREHOUSE = var.lambda_snowflake_warehouse
    SNOWFLAKE_ROLE      = var.lambda_snowflake_role
    SNOWFLAKE_USER      = var.lambda_snowflake_user
    BUCKET_NAME         = module.s3_bucket.s3_bucket_name_output
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.s3_input_bucket_policy.arn
  ]
}

module "lambda_documents_knr_payments_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git?ref=1.0.1"

  environment_name = var.environment
  service_name     = var.lambda_name
}

# create datadog dashboards.
module "datadog_lambda_documents_knr_payments" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment                       = var.environment
  service_name                      = var.lambda_name
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-The_Orchard-documents-public"
  escalation_notification_endpoints = "@slack-The_Orchard-documents-public"
}

module "lambda_documents_knr_payments_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.lambda_name
  teams              = [var.environment]
  application_family = var.application_family
}

# create invoke policy for jenkins to run job

data "aws_iam_policy_document" "knr_payments_invoke_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
      "lambda:GetFunction",
      "lambda:GetFunctionConfiguration",
      "lambda:GetPolicy",
      "lambda:GetAlias",
      "lambda:ListVersionsByFunction",
      "lambda:ListAliases",
      "lambda:GetFunctionEventInvokeConfig"
    ]
    resources = [
      module.lambda_documents_knr_payments.lambda_arn
    ]
  }
}

data "aws_iam_policy_document" "jenkins_knr_payments_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "knr_payments_invoke_role" {
  name                  = "${var.environment}-knr-payments-invoke-role"
  force_detach_policies = true
  assume_role_policy    = data.aws_iam_policy_document.jenkins_knr_payments_assume_role_policy.json

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
  }
}

resource "aws_iam_policy" "knr_payments_invoke_policy" {
  name   = "${var.environment}-knr-payments-invoke-policy"
  policy = data.aws_iam_policy_document.knr_payments_invoke_policy_document.json

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.service_name
    terraformed        = "true"
  }
}

resource "aws_iam_role_policy_attachment" "knr_payments_invoke_policy_attachment" {
  role       = aws_iam_role.knr_payments_invoke_role.name
  policy_arn = aws_iam_policy.knr_payments_invoke_policy.arn
}

module "secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each           = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
}